[arch-commits] Commit in haskell-fgl-arbitrary/repos (2 files)

[Felix Yan]

    Date: Friday, November 12, 2021 @ 00:26:54
  Author: felixonmars
Revision: 1042757

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-fgl-arbitrary/repos/community-staging-x86_64/
  haskell-fgl-arbitrary/repos/community-staging-x86_64/PKGBUILD
    (from rev 1042756, haskell-fgl-arbitrary/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-fgl-arbitrary/repos/community-staging-x86_64/PKGBUILD (from rev 1042756, haskell-fgl-arbitrary/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-12 00:26:54 UTC (rev 1042757)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=fgl-arbitrary
+pkgname=haskell-fgl-arbitrary
+pkgver=0.2.0.6
+pkgrel=36
+pkgdesc="QuickCheck support for fgl"
+url="https://github.com/haskell/fgl.git"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-quickcheck' 'haskell-fgl')
+makedepends=('ghc' 'uusi' 'haskell-hspec')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('6cf210a2ecbda21059647008cc8d85969308b21d18690f82d5f70d92435bd3d7')
+
+prepare() {
+  cd $_hkgname-$pkgver
+  uusi -u hspec $_hkgname.cabal
+}
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test --show-details=direct
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}