[arch-commits] Commit in haskell-hedgehog/repos (2 files)

[Felix Yan]

    Date: Friday, November 12, 2021 @ 03:39:30
  Author: felixonmars
Revision: 1043077

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hedgehog/repos/community-staging-x86_64/
  haskell-hedgehog/repos/community-staging-x86_64/PKGBUILD
    (from rev 1043076, haskell-hedgehog/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: haskell-hedgehog/repos/community-staging-x86_64/PKGBUILD (from rev 1043076, haskell-hedgehog/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-12 03:39:30 UTC (rev 1043077)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=hedgehog
+pkgname=haskell-hedgehog
+pkgver=1.0.5
+pkgrel=62
+pkgdesc="A modern property-based testing system"
+url="https://hedgehog.qa"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ansi-terminal' 'haskell-async' 'haskell-concurrent-output'
+         'haskell-erf' 'haskell-lifted-async' 'haskell-mmorph' 'haskell-monad-control'
+         'haskell-pretty-show' 'haskell-primitive' 'haskell-random' 'haskell-resourcet'
+         'haskell-transformers-base' 'haskell-wl-pprint-annotated')
+makedepends=('ghc' 'uusi')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('03a1bd64451ce90ce7bac67e9f558a97b33cb2f7eeec7885c76558f34018eb794f82344563c6b511094e9cf610a6c0f4c0a229455e57df8729fc093ec212dd98')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    gen-setup
+    uusi -u mmorph $_hkgname.cabal
+} 
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}