[arch-commits] Commit in haskell-wai-extra/repos (2 files)

[Felix Yan]

    Date: Friday, November 12, 2021 @ 12:03:52
  Author: felixonmars
Revision: 1043619

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-wai-extra/repos/community-staging-x86_64/
  haskell-wai-extra/repos/community-staging-x86_64/PKGBUILD
    (from rev 1043618, haskell-wai-extra/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: haskell-wai-extra/repos/community-staging-x86_64/PKGBUILD (from rev 1043618, haskell-wai-extra/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-12 12:03:52 UTC (rev 1043619)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=wai-extra
+pkgname=haskell-wai-extra
+pkgver=3.1.7
+pkgrel=11
+pkgdesc="Provides some basic WAI handlers and middleware."
+url="https://github.com/yesodweb/wai"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-ansi-terminal' 'haskell-base64-bytestring'
+         'haskell-case-insensitive' 'haskell-cookie' 'haskell-data-default-class'
+         'haskell-fast-logger' 'haskell-http-types' 'haskell-http2' 'haskell-iproute'
+         'haskell-network' 'haskell-resourcet' 'haskell-streaming-commons'
+         'haskell-vault' 'haskell-wai' 'haskell-wai-logger' 'haskell-word8' 'haskell-hunit'
+         'haskell-call-stack')
+makedepends=('ghc' 'haskell-hspec' 'haskell-zlib')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('b898ddce8d89cd82336543d29aacf63c58c2f6d714bbf2bc184721ad6d740d9e75806b095dd0369d6effbe6d3c0eb91c9f0a1a5ffdd795e741443f5b7458c876')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+            -f-build-example
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}