[arch-commits] Commit in haskell-githash/repos (2 files)

[Felix Yan]

    Date: Friday, November 12, 2021 @ 12:34:26
  Author: felixonmars
Revision: 1043655

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-githash/repos/community-staging-x86_64/
  haskell-githash/repos/community-staging-x86_64/PKGBUILD
    (from rev 1043654, haskell-githash/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-githash/repos/community-staging-x86_64/PKGBUILD (from rev 1043654, haskell-githash/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-12 12:34:26 UTC (rev 1043655)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=githash
+pkgname=haskell-githash
+pkgver=0.1.6.2
+pkgrel=10
+pkgdesc="Some handy Template Haskell splices for including the current git hash and branch in the code of your project"
+url="https://github.com/snoyberg/githash"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-th-compat' 'git')
+makedepends=('ghc' 'haskell-hpack' 'haskell-hspec' 'haskell-temporary' 'haskell-unliftio')
+source=("git+https://github.com/snoyberg/githash.git#tag=githash-$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+    cd $_hkgname
+    hpack
+}
+
+build() {
+    cd $_hkgname
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}