[arch-commits] Commit in python-proxy.py/repos (community-any community-any/PKGBUILD)

[Jonas Witschel]

    Date: Friday, November 12, 2021 @ 14:06:47
  Author: diabonas
Revision: 1043753

archrelease: copy trunk to community-any

Added:
  python-proxy.py/repos/community-any/
  python-proxy.py/repos/community-any/PKGBUILD
    (from rev 1043752, python-proxy.py/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: python-proxy.py/repos/community-any/PKGBUILD (from rev 1043752, python-proxy.py/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2021-11-12 14:06:47 UTC (rev 1043753)
@@ -0,0 +1,38 @@
+# Maintainer: Jonas Witschel <diabonas at archlinux.org>
+pkgname=python-proxy.py
+pkgver=2.3.1
+# unfortunately there are no tags, and the tarball on PyPi is missing tests
+_commit=82d562b7d6b068ea706634f97e6a086f5209df61 
+pkgrel=1
+pkgdesc='Lightweight HTTP, HTTPS, HTTP2 and WebSockets proxy server'
+arch=('any')
+url='https://github.com/abhinavsingh/proxy.py'
+license=('BSD')
+depends=('python' 'python-typing_extensions')
+makedepends=('git' 'python-setuptools')
+checkdepends=('python-paramiko')
+optdepends=('python-paramiko: proxy over SSH tunnel support')
+source=("git+$url#commit=$_commit")
+sha512sums=('SKIP')
+
+prepare() {
+	cd "${pkgname#python-}"
+	# Remove strict version dependency for typing_extensions
+	sed -i 's/==.*//' requirements.txt
+}
+
+build() {
+	cd "${pkgname#python-}"
+	python setup.py build
+}
+
+check() {
+	cd "${pkgname#python-}"
+	python setup.py test
+}
+
+package() {
+	cd "${pkgname#python-}"
+	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+	install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
+}