[arch-commits] Commit in haskell-ghc-exactprint/repos (2 files)

[Felix Yan]

    Date: Saturday, November 13, 2021 @ 18:01:08
  Author: felixonmars
Revision: 1045784

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-ghc-exactprint/repos/community-staging-x86_64/
  haskell-ghc-exactprint/repos/community-staging-x86_64/PKGBUILD
    (from rev 1045783, haskell-ghc-exactprint/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-ghc-exactprint/repos/community-staging-x86_64/PKGBUILD (from rev 1045783, haskell-ghc-exactprint/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-13 18:01:08 UTC (rev 1045784)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=ghc-exactprint
+pkgname=haskell-ghc-exactprint
+pkgver=0.6.4
+pkgrel=48
+pkgdesc="ExactPrint for GHC"
+url="https://github.com/alanz/ghc-exactprint.git"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-free' 'haskell-ghc-paths' 'haskell-syb')
+makedepends=('ghc' 'haskell-diff' 'haskell-hunit' 'haskell-filemanip' 'haskell-silently')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha512sums=('a269d270464ee34493117e672c819eefe369bb88bd6043284631f67b3c711e6559f7d6352da2080bc65749767305ea75b9bc43e594bdfcd81ea6cb02986a8bff')
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test --show-details=direct
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}