[arch-commits] Commit in haskell-hasql-transaction/repos (2 files)

[Felix Yan]

    Date: Sunday, November 14, 2021 @ 15:32:10
  Author: felixonmars
Revision: 1047532

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hasql-transaction/repos/community-staging-x86_64/
  haskell-hasql-transaction/repos/community-staging-x86_64/PKGBUILD
    (from rev 1047531, haskell-hasql-transaction/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: haskell-hasql-transaction/repos/community-staging-x86_64/PKGBUILD (from rev 1047531, haskell-hasql-transaction/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-14 15:32:10 UTC (rev 1047532)
@@ -0,0 +1,53 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=hasql-transaction
+pkgname=haskell-hasql-transaction
+pkgver=1.0.1
+pkgrel=43
+pkgdesc="A composable abstraction over the retryable transactions for Hasql"
+url="https://github.com/nikita-volkov/hasql-transaction"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-bytestring-tree-builder' 'haskell-contravariant'
+         'haskell-contravariant-extras' 'haskell-hasql')
+makedepends=('ghc' 'uusi' 'haskell-async' 'haskell-rerebase')
+checkdepends=('postgresql' 'pifpaf')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('92689f9ffd443e9fcce5c024871492774687c98a7b906040af4f175e268f77e9dfa5520e8d95b056bd0ed264a63e5d38d0aa8759ec7e0ba9ebd697262428b8f4')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/5432/9824/' conflicts-test/Main.hs
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+
+    eval $(pifpaf run postgresql --host 127.0.0.1)
+    createuser -s postgres
+    runhaskell Setup test --show-details=direct
+    pifpaf_stop
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}