[arch-commits] Commit in haskell-hls-call-hierarchy-plugin/repos (2 files)

[Felix Yan]

    Date: Monday, November 15, 2021 @ 04:07:31
  Author: felixonmars
Revision: 1047838

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hls-call-hierarchy-plugin/repos/community-staging-x86_64/
  haskell-hls-call-hierarchy-plugin/repos/community-staging-x86_64/PKGBUILD
    (from rev 1047837, haskell-hls-call-hierarchy-plugin/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: haskell-hls-call-hierarchy-plugin/repos/community-staging-x86_64/PKGBUILD (from rev 1047837, haskell-hls-call-hierarchy-plugin/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-15 04:07:31 UTC (rev 1047838)
@@ -0,0 +1,53 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=hls-call-hierarchy-plugin
+pkgname=haskell-hls-call-hierarchy-plugin
+pkgver=1.0.0.0
+pkgrel=18
+pkgdesc="Call hierarchy plugin for Haskell Language Server"
+url="https://hackage.haskell.org/package/hls-call-hierarchy-plugin"
+license=("Apache")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-extra' 'haskell-ghc' 'haskell-ghc-api-compat'
+         'haskell-ghcide' 'haskell-hiedb' 'haskell-hls-plugin-api' 'haskell-lens' 'haskell-lsp'
+         'haskell-sqlite-simple' 'haskell-unordered-containers')
+makedepends=('ghc' 'uusi' 'haskell-hls-test-utils' 'haskell-lsp-test')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('4b3103a98ec57c9f050ffd1c534a0e23b1bfcbe78dda441c351b874939ce34a8')
+
+prepare() {
+  cd $_hkgname-$pkgver
+  gen-setup
+  uusi -u ghc-api-compat $_hkgname.cabal
+}
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test --show-details=direct
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}