[arch-commits] Commit in python-h5py-openmpi/repos/community-x86_64 (2 files)

[Bruno Pagani]

    Date: Tuesday, November 16, 2021 @ 21:06:14
  Author: archange
Revision: 1048851

archrelease: copy trunk to community-x86_64

Added:
  python-h5py-openmpi/repos/community-x86_64/PKGBUILD
    (from rev 1048850, python-h5py-openmpi/trunk/PKGBUILD)
Deleted:
  python-h5py-openmpi/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |   98 ++++++++++++++++++++++++++++++-------------------------------
 1 file changed, 49 insertions(+), 49 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2021-11-16 21:05:50 UTC (rev 1048850)
+++ PKGBUILD	2021-11-16 21:06:14 UTC (rev 1048851)
@@ -1,49 +0,0 @@
-# Maintainer: Bruno Pagani <archange at archlinux.org>
-# Contributor: Joey Dumont <joey.dumont at gmail.com>
-
-_pkg=h5py
-_mpi=openmpi
-pkgname=python-${_pkg}-${_mpi}
-pkgver=3.5.0
-pkgrel=1
-pkgdesc="General-purpose Python bindings for the HDF5 library (${_mpi} version)"
-arch=(x86_64)
-url="https://www.h5py.org/"
-license=(BSD)
-depends=(hdf5-${_mpi} liblzf python-numpy python-mpi4py)
-makedepends=(cython python-pkgconfig python-setuptools)
-checkdepends=(inetutils python-pytest python-pytest-mpi python-pytables)
-conflicts=(python-h5py)
-provides=(python-h5py)
-source=(https://files.pythonhosted.org/packages/source/h/${_pkg}/${_pkg}-${pkgver}.tar.gz)
-sha256sums=('77c7be4001ac7d3ed80477de5b6942501d782de1bbe4886597bdfec2a7ab821f')
-validpgpkeys=(AC47F71DB275ECD0B3DA46E857FA4540DD4EFCF7 # Thomas A Caswell (Brookhaven National Lab) <tcaswell at bnl.gov>
-              96B7334D7610EE3E68AFFE589E027116943D6A8B) # Thomas A Caswell <tcaswell at bnl.gov> (new key)
-# See https://github.com/h5py/h5py/issues/1299 about lack of GPG sigs for recent releases
-
-prepare() {
-  cd ${_pkg}-${pkgver}
-  # Allow our mpi4py, numpy versions
-  sed -i 's/mpi4py ==/mpi4py >=/g' setup.py
-  sed -i 's/numpy ==/numpy >=/g' setup.py
-  # Remove RPATH
-  sed -i "s/settings\\['runtime_library_dirs'\\] = settings\\['library_dirs'\\]/pass/" setup_build.py
-}
-
-build() {
-  export CC=mpicc
-  cd ${_pkg}-${pkgver}
-  HDF5_MPI="ON" H5PY_SYSTEM_LZF=1 python setup.py build
-}
-
-check() {
-  local python_version=$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')
-  export H5PY_TEST_CHECK_FILTERS=1
-  PYTHONPATH="$PWD/${_pkg}-${pkgver}/build/lib.linux-$CARCH-${python_version}" python -m pytest --pyargs h5py -rxXs --color=yes --with-mpi
-}
-
-package() {
-  cd ${_pkg}-${pkgver}
-  HDF5_MPI="ON" python setup.py install --root="${pkgdir}" --skip-build --optimize=1
-  install -Dm644 licenses/license.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}/
-}

Copied: python-h5py-openmpi/repos/community-x86_64/PKGBUILD (from rev 1048850, python-h5py-openmpi/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2021-11-16 21:06:14 UTC (rev 1048851)
@@ -0,0 +1,49 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Joey Dumont <joey.dumont at gmail.com>
+
+_pkg=h5py
+_mpi=openmpi
+pkgname=python-${_pkg}-${_mpi}
+pkgver=3.6.0
+pkgrel=1
+pkgdesc="General-purpose Python bindings for the HDF5 library (${_mpi} version)"
+arch=(x86_64)
+url="https://www.h5py.org/"
+license=(BSD)
+depends=(hdf5-${_mpi} liblzf python-numpy python-mpi4py)
+makedepends=(cython python-pkgconfig python-setuptools)
+checkdepends=(inetutils python-pytest python-pytest-mpi python-pytables)
+conflicts=(python-h5py)
+provides=(python-h5py)
+source=(https://files.pythonhosted.org/packages/source/h/${_pkg}/${_pkg}-${pkgver}.tar.gz)
+sha256sums=('8752d2814a92aba4e2b2a5922d2782d0029102d99caaf3c201a566bc0b40db29')
+validpgpkeys=(AC47F71DB275ECD0B3DA46E857FA4540DD4EFCF7 # Thomas A Caswell (Brookhaven National Lab) <tcaswell at bnl.gov>
+              96B7334D7610EE3E68AFFE589E027116943D6A8B) # Thomas A Caswell <tcaswell at bnl.gov> (new key)
+# See https://github.com/h5py/h5py/issues/1299 about lack of GPG sigs for recent releases
+
+prepare() {
+  cd ${_pkg}-${pkgver}
+  # Allow our mpi4py, numpy versions
+  sed -i 's/mpi4py ==/mpi4py >=/g' setup.py
+  sed -i 's/numpy ==/numpy >=/g' setup.py
+  # Remove RPATH
+  sed -i "s/settings\\['runtime_library_dirs'\\] = settings\\['library_dirs'\\]/pass/" setup_build.py
+}
+
+build() {
+  export CC=mpicc
+  cd ${_pkg}-${pkgver}
+  HDF5_MPI="ON" H5PY_SYSTEM_LZF=1 python setup.py build
+}
+
+check() {
+  local python_version=$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')
+  export H5PY_TEST_CHECK_FILTERS=1
+  PYTHONPATH="$PWD/${_pkg}-${pkgver}/build/lib.linux-$CARCH-${python_version}" python -m pytest --pyargs h5py -rxXs --color=yes --with-mpi
+}
+
+package() {
+  cd ${_pkg}-${pkgver}
+  HDF5_MPI="ON" python setup.py install --root="${pkgdir}" --skip-build --optimize=1
+  install -Dm644 licenses/license.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}