[arch-commits] Commit in haskell-libbf/repos (2 files)

[Felix Yan]

    Date: Thursday, November 18, 2021 @ 01:37:49
  Author: felixonmars
Revision: 1051599

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-libbf/repos/community-staging-x86_64/
  haskell-libbf/repos/community-staging-x86_64/PKGBUILD
    (from rev 1051598, haskell-libbf/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: haskell-libbf/repos/community-staging-x86_64/PKGBUILD (from rev 1051598, haskell-libbf/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-18 01:37:49 UTC (rev 1051599)
@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=libBF
+pkgname=haskell-libbf
+pkgver=0.6.2
+pkgrel=46
+pkgdesc="A binding to the libBF library"
+url="https://github.com/GaloisInc/libBF-hs"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'libbf' 'haskell-hashable')
+makedepends=('ghc')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('d5ced83dd9d5c6b2b39d0ce86894d01a275e7086f618588966bc0fea0ac64803ca469b2a1268e1779e99569a3c2aaae69c02a0e9ac4e062e2b8d31151d33a771')
+
+build() {
+    cd $_hkgname-$pkgver    
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+        -fsystem-libbf
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}