[arch-commits] Commit in haskell-vector-builder/repos (2 files)

[Felix Yan]

    Date: Thursday, November 18, 2021 @ 22:19:56
  Author: felixonmars
Revision: 1052660

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-vector-builder/repos/community-staging-x86_64/
  haskell-vector-builder/repos/community-staging-x86_64/PKGBUILD
    (from rev 1052659, haskell-vector-builder/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: haskell-vector-builder/repos/community-staging-x86_64/PKGBUILD (from rev 1052659, haskell-vector-builder/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-18 22:19:56 UTC (rev 1052660)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=vector-builder
+pkgname=haskell-vector-builder
+pkgver=0.3.8.2
+pkgrel=34
+pkgdesc="Vector builder"
+url="https://github.com/nikita-volkov/vector-builder"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-vector')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-attoparsec' 'haskell-quickcheck-instances'
+             'haskell-rerebase' 'haskell-tasty' 'haskell-tasty-hunit' 'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('7ad6c01f21ef38445f81389ffac6d8a12de95e36dfbb4d83f011586c35a5c569e58c827d27a6e60a18b0dff9d0dc56f2ab6927c1dc49d5cc2bd2663726b909f0')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}