[arch-commits] Commit in libmbim/trunk (PKGBUILD)

[Jan Steffens]

    Date: Thursday, November 18, 2021 @ 22:51:20
  Author: heftig
Revision: 428631

1.26.2-1

Modified:
  libmbim/trunk/PKGBUILD

----------+
 PKGBUILD |   24 +++++++++---------------
 1 file changed, 9 insertions(+), 15 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2021-11-18 22:49:57 UTC (rev 428630)
+++ PKGBUILD	2021-11-18 22:51:20 UTC (rev 428631)
@@ -1,43 +1,37 @@
 # Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
 
 pkgname=libmbim
-pkgver=1.26.0
-pkgrel=2
+pkgver=1.26.2
+pkgrel=1
 pkgdesc="MBIM modem protocol helper library"
 arch=(x86_64)
 url="https://www.freedesktop.org/wiki/Software/libmbim/"
 license=(GPL2)
 depends=(glib2 bash systemd)
-makedepends=(gtk-doc python git help2man gobject-introspection)
+makedepends=(gtk-doc meson git help2man gobject-introspection bash-completion)
 provides=(libmbim-glib.so)
-_commit=717067603d82c14452e70fa24cacb60ac7688685  # tags/1.26.0
+_commit=55d51a8a76921b478a75b79a8695b37d989e4868  # tags/1.26.2
 source=("git+https://gitlab.freedesktop.org/mobile-broadband/libmbim.git#commit=$_commit")
 sha256sums=('SKIP')
 
 pkgver() {
   cd $pkgname
-  git describe --tags | sed 's/-rc/rc/;s/-/+/g'
+  git describe --tags | sed 's/-rc/rc/;s/[^-]*-g/r&/;s/-/+/g'
 }
 
 prepare() {
   cd $pkgname
-  NOCONFIGURE=1 ./autogen.sh
 }
 
 build() {
-  cd $pkgname
-  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
-    --libexecdir=/usr/lib --disable-static --enable-gtk-doc \
-    --enable-compile-warnings=yes
-  make
+  arch-meson $pkgname build -D gtk_doc=true
+  meson compile -C build
 }
 
 check() {
-  cd $pkgname
-  make check
+  meson test -C build --print-errorlogs
 }
 
 package() {
-  cd $pkgname
-  make DESTDIR="$pkgdir" install
+  meson install -C build --destdir "$pkgdir"
 }