[arch-commits] Commit in nvidia/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Jan Steffens]

    Date: Thursday, November 18, 2021 @ 23:22:14
  Author: heftig
Revision: 428652

archrelease: copy trunk to testing-x86_64

Added:
  nvidia/repos/testing-x86_64/
  nvidia/repos/testing-x86_64/PKGBUILD
    (from rev 428651, nvidia/trunk/PKGBUILD)

----------+
 PKGBUILD |   36 ++++++++++++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)

Copied: nvidia/repos/testing-x86_64/PKGBUILD (from rev 428651, nvidia/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2021-11-18 23:22:14 UTC (rev 428652)
@@ -0,0 +1,36 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Thomas Baechler <thomas at archlinux.org>
+
+pkgname=nvidia
+pkgver=495.44
+pkgrel=10
+pkgdesc="NVIDIA drivers for linux"
+arch=('x86_64')
+url="https://www.nvidia.com/"
+makedepends=('linux-headers' "nvidia-dkms=$pkgver")
+provides=('NVIDIA-MODULE')
+license=('custom')
+options=('!strip')
+
+build() {
+    _kernver=$(</usr/src/linux/version)
+
+    fakeroot dkms build --dkmstree "${srcdir}" -m nvidia/${pkgver} -k ${_kernver}
+}
+
+package() {
+    depends=('linux' "nvidia-utils=${pkgver}" 'libglvnd')
+
+    _kernver="$(</usr/src/linux/version)"
+
+    install -Dt "${pkgdir}/usr/lib/modules/${_kernver}/extramodules" -m644 nvidia/${pkgver}/${_kernver}/${CARCH}/module/*
+
+    # compress each module individually
+    find "$pkgdir" -name '*.ko' -exec xz -T1 {} +
+
+    echo "blacklist nouveau" | install -Dm644 /dev/stdin "${pkgdir}/usr/lib/modprobe.d/${pkgname}.conf"
+    echo "nvidia-uvm" | install -Dm644 /dev/stdin "${pkgdir}/usr/lib/modules-load.d/${pkgname}.conf"
+
+    install -Dm644 /usr/share/licenses/nvidia-dkms/LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}