[arch-commits] Commit in lmms/repos (3 files)

[David Runge]

    Date: Friday, November 19, 2021 @ 18:24:22
  Author: dvzrv
Revision: 1052788

archrelease: copy trunk to community-staging-x86_64

Added:
  lmms/repos/community-staging-x86_64/
  lmms/repos/community-staging-x86_64/PKGBUILD
    (from rev 1052787, lmms/trunk/PKGBUILD)
  lmms/repos/community-staging-x86_64/lmms-1.2.2-wine.patch
    (from rev 1052787, lmms/trunk/lmms-1.2.2-wine.patch)

-----------------------+
 PKGBUILD              |   64 ++++++++++++++++++++++++++++++++++++++++++++++++
 lmms-1.2.2-wine.patch |   24 ++++++++++++++++++
 2 files changed, 88 insertions(+)

Copied: lmms/repos/community-staging-x86_64/PKGBUILD (from rev 1052787, lmms/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-19 18:24:22 UTC (rev 1052788)
@@ -0,0 +1,64 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Lukas Fleischer <lfleischer at archlinux.org>
+# Contributor: Shinlun Hsieh <yngwiexx at yahoo.com.tw>
+# Contributor: Mateusz Herych <heniekk at gmail.com>
+# Contributor: Storyteller <spiralsorrow at hotmail.com>
+
+pkgname=lmms
+pkgver=1.2.2
+pkgrel=6
+pkgdesc='The Linux MultiMedia Studio'
+arch=(x86_64)
+url="https://lmms.io"
+license=(GPL2)
+groups=(pro-audio)
+depends=(gcc-libs glibc lame libx11 libxcb qt5-base qt5-x11extras sdl sndio
+zlib)
+makedepends=(alsa-lib bash-completion carla cmake doxygen extra-cmake-modules
+fftw fltk fluidsynth freetype2 jack ladspa libgig libogg libpulse libsamplerate
+libsndfile libvorbis portaudio qt5-tools stk wine)
+optdepends=('pulseaudio: pulseaudio support'
+            'wine: VST plugin support')
+options=(!lto)
+source=("https://github.com/${pkgname}/${pkgname}/releases/download/v${pkgver}/${pkgname}_${pkgver}.tar.xz"
+        "${pkgname}-1.2.2-wine.patch"
+)
+sha512sums=('df74d9e938f1c3807e9941b11db4ccfe9450e23b723c82774de15b7666ac39f1bfdd8519231e28849f994628190ecc92fa05d55bbc0b50a4421f2d183e729028'
+            '6dc97f6961a7eda8826ca28e2c3fb5cb69f73423d8809b2fba993120c7ebc3ff1f0dee91b2b7e304341bae89b72348ff86434c2637cfe58af8c6e6e28f43c692')
+b2sums=('8b561068194e9a4af8260675e784c25a92b6b2f731c29b677cbc16581306bbadcf27ea529adbcd735ff4adffedf3dd98ec7b2d89428a63ea600d022ecdae58e4'
+        '4b42d098c91871bcee9fbdc9486d1273be535f8c4ce837c0f7132cb2ed69739a60551e5c3f0c90059e83ae5d98d5887c5d00d597c785776eff854c42ede8a645')
+
+prepare() {
+  mv -v "${pkgname}" "${pkgname}-${pkgver}"
+  cd "${pkgname}-${pkgver}"
+  # prevent cmake from doing regular expressions breaking the build
+  patch -Np1 -i ../"${pkgname}-1.2.2-wine.patch"
+}
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  export LDFLAGS="${LDFLAGS}"
+  cmake -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_BUILD_TYPE='None' \
+        -DWANT_QT5=ON \
+        -DWANT_SOUNDIO=OFF \
+        -DCMAKE_INSTALL_LIBDIR=lib \
+        -DCMAKE_MODULE_PATH=/usr/share/ECM/find-modules \
+        -DCMAKE_PREFIX_PATH=/usr/include/wine/windows \
+        -DWINE_INCLUDE_DIR=/usr/include/wine/windows \
+        -DWINE_LIBRARY=/usr/lib32/wine \
+        -DOpenGL_GL_PREFERENCE=GLVND \
+        -W no-dev \
+        -B build \
+        -S .
+  make VERBOSE=1 -C build
+}
+
+package() {
+  depends+=(libasound.so libfftw3f.so libfltk.so libfluidsynth.so libgig.so
+  libogg.so libportaudio.so libpulse.so libstk-4.6.2.so libvorbis.so
+  libvorbisenc.so libvorbisfile.so libsamplerate.so)
+
+  cd "${pkgname}-${pkgver}"
+  make VERBOSE=1 DESTDIR="${pkgdir}" install -C build
+}

Copied: lmms/repos/community-staging-x86_64/lmms-1.2.2-wine.patch (from rev 1052787, lmms/trunk/lmms-1.2.2-wine.patch)
===================================================================
--- community-staging-x86_64/lmms-1.2.2-wine.patch	                        (rev 0)
+++ community-staging-x86_64/lmms-1.2.2-wine.patch	2021-11-19 18:24:22 UTC (rev 1052788)
@@ -0,0 +1,24 @@
+diff -ruN a/cmake/modules/FindWine.cmake b/cmake/modules/FindWine.cmake
+--- a/cmake/modules/FindWine.cmake	2018-11-03 02:43:42.000000000 +0100
++++ b/cmake/modules/FindWine.cmake	2021-06-03 22:37:41.258182544 +0200
+@@ -31,7 +31,7 @@
+ 		# WineHQ (/opt/wine-stable, /opt/wine-devel, /opt/wine-staging)
+ 		STRING(REPLACE "/lib64/wine/" "/lib/wine/" FLAG "${FLAG}")
+ 
+-		STRING(REGEX REPLACE "/wine/libwinecrt0.a.*" "" WINE_LIBRARY_FIX "${FLAG}")
++		STRING(REGEX REPLACE "libwinecrt0.a.*" "" WINE_LIBRARY_FIX "${FLAG}")
+ 		SET(WINE_LIBRARY_FIX "${WINE_LIBRARY_FIX}/")
+ 	ENDIF()
+ ENDFOREACH()
+diff -ruN a/plugins/vst_base/CMakeLists.txt b/plugins/vst_base/CMakeLists.txt
+--- a/plugins/vst_base/CMakeLists.txt	2018-11-03 02:43:42.000000000 +0100
++++ b/plugins/vst_base/CMakeLists.txt	2021-06-03 22:37:45.881530269 +0200
+@@ -38,7 +38,7 @@
+ IF(LMMS_HOST_X86_64)
+ 	SET(EXTRA_FLAGS -m32)
+ 	IF(WINE_LIBRARY_FIX)
+-		SET(EXTRA_FLAGS ${EXTRA_FLAGS} -nodefaultlibs ${WINE_LIBRARY_FIX}wine/libwinecrt0.a -L${WINE_LIBRARY_FIX}wine/ -luser32 -lkernel32 -lgdi32)
++		SET(EXTRA_FLAGS ${EXTRA_FLAGS} -nodefaultlibs ${WINE_LIBRARY_FIX}libwinecrt0.a -L${WINE_LIBRARY_FIX} -luser32 -lkernel32 -lgdi32)
+ 	ENDIF()
+ ENDIF(LMMS_HOST_X86_64)
+