[arch-commits] Commit in git-delta/repos (2 files)

[George Rawlinson]

    Date: Saturday, November 20, 2021 @ 21:07:41
  Author: grawlinson
Revision: 1052895

archrelease: copy trunk to community-staging-x86_64

Added:
  git-delta/repos/community-staging-x86_64/
  git-delta/repos/community-staging-x86_64/PKGBUILD
    (from rev 1052894, git-delta/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: git-delta/repos/community-staging-x86_64/PKGBUILD (from rev 1052894, git-delta/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-20 21:07:41 UTC (rev 1052895)
@@ -0,0 +1,55 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor:  Kr1ss $(echo \<kr1ss+x-yandex+com\>|sed s/\+/./g\;s/\-/@/)
+# Contributor : ccorn
+
+pkgname=git-delta
+_pkgname=delta
+pkgver=0.9.2
+pkgrel=2
+pkgdesc='Syntax-highlighting pager for git and diff output'
+arch=('x86_64')
+url="https://github.com/dandavison/delta"
+license=('MIT')
+depends=('libgit2')
+makedepends=('rust')
+checkdepends=('git')
+options=('!lto')
+source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
+b2sums=('46ed5598965553f6c9df28863efd0304deecedc41970701fe46d8698494cdfd371bc463845586b9e3a1150034a36abde403d6eb5185c79bf65d918418690beea')
+
+prepare() {
+  cd "$_pkgname-$pkgver"
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "$_pkgname-$pkgver"
+  cargo build --frozen --release --all-features
+}
+
+check() {
+  cd "$_pkgname-$pkgver"
+  # some tests hang for 60+ seconds, find out why
+  # took my machine ~ 470 seconds
+  cargo test --frozen --all-features
+}
+
+package() {
+  cd "$_pkgname-$pkgver"
+
+  # binary
+  install -vDm755 -t "$pkgdir/usr/bin" target/release/delta
+
+  # license
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+
+  # shell auto-completions
+  install -vDm644 etc/completion/completion.bash \
+    "$pkgdir/usr/share/bash-completion/completions/$_pkgname"
+  install -vDm644 etc/completion/completion.zsh \
+    "$pkgdir/usr/share/zsh/site-functions/_$_pkgname"
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
+}