[arch-commits] Commit in libcap/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[David Runge]

    Date: Sunday, November 21, 2021 @ 11:56:16
  Author: dvzrv
Revision: 428737

archrelease: copy trunk to staging-x86_64

Added:
  libcap/repos/staging-x86_64/
  libcap/repos/staging-x86_64/PKGBUILD
    (from rev 428736, libcap/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: libcap/repos/staging-x86_64/PKGBUILD (from rev 428736, libcap/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2021-11-21 11:56:16 UTC (rev 428737)
@@ -0,0 +1,40 @@
+# Maintainer:  David Runge <dvzrv at archlinux.org>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Allan McRae <allan at archlinux.org>
+# Contributor: Hugo Doria <hugo at archlinux.org>
+
+pkgname=libcap
+pkgver=2.61
+pkgrel=1
+pkgdesc="POSIX 1003.1e capabilities"
+arch=(x86_64)
+url="https://sites.google.com/site/fullycapable/"
+license=(GPL2)
+depends=(glibc pam)
+makedepends=(linux-api-headers)
+provides=(libcap.so libpsx.so)
+source=("https://kernel.org/pub/linux/libs/security/linux-privs/${pkgname}2/${pkgname}-$pkgver.tar."{xz,sign}
+)
+sha512sums=('40096bf511d1c45e36f5d7f24e49c709528f3f01fcadd47b6ac40a7e8d5f1705b29b4cc56356b030639f67d0641b9f4e7c19449c3c7f4f77a4070c35745b465c'
+            'SKIP')
+b2sums=('50874d3510ab2476aaceb775314d98744736aacd7364a23827756caa160c101e8bc890b7c33b5e19df8b30bb6b3b1c2be323e4b6a963f97e9ee557e86b4f13a0'
+        'SKIP')
+validpgpkeys=(38A644698C69787344E954CE29EE848AE2CCF3F4) # Andrew G. Morgan <morgan at kernel.org>
+
+build() {
+  cd "$pkgname-$pkgver"
+  make DYNAMIC=yes KERNEL_HEADERS='/usr/include' lib='lib' prefix='/usr' sbindir='bin'
+}
+
+check() {
+  cd "$pkgname-$pkgver"
+  make -k test
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  make DESTDIR="$pkgdir" RAISE_SETFCAP='no' lib='lib' prefix='/usr' sbindir='bin' install
+  # docs
+  install -vDm 644 {CHANGELOG,README} -t "${pkgdir}/usr/share/doc/${pkgname}/"
+  install -vDm 644 pam_cap/capability.conf -t "$pkgdir/usr/share/doc/$pkgname/examples/"
+}