[arch-commits] Commit in geany-plugins/repos (2 files)

[David Runge]

    Date: Sunday, November 21, 2021 @ 14:08:18
  Author: dvzrv
Revision: 1053000

archrelease: copy trunk to community-staging-x86_64

Added:
  geany-plugins/repos/community-staging-x86_64/
  geany-plugins/repos/community-staging-x86_64/PKGBUILD
    (from rev 1052999, geany-plugins/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: geany-plugins/repos/community-staging-x86_64/PKGBUILD (from rev 1052999, geany-plugins/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-21 14:08:18 UTC (rev 1053000)
@@ -0,0 +1,42 @@
+# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
+# Contributor: Angel 'angvp' Velasquez <angvp at archlinux.org>
+# Contributor: Gerardo Exequiel Pozzi <vmlinuz386 at gmail.com>
+# Contributor: Patrick Melo <patrick at patrickmelo.eti.br>
+
+pkgname=geany-plugins
+pkgver=1.38
+pkgrel=2
+pkgdesc='Plugins for Geany'
+arch=(x86_64)
+url='https://plugins.geany.org/'
+license=(GPL)
+depends=(ctpl "geany>=$pkgver" gpgme gtkspell3 libgit2 lua51 python vte3 webkit2gtk)
+makedepends=(cppcheck intltool)
+source=("$url$pkgname/$pkgname-$pkgver.tar.bz2"{,.sig})
+b2sums=('a2fd9e59218e4b5359b910ccff8d0a6504845081f827d2f1c798ea6401914e8e01222c784a76ab0a126f5fe07c8aa86018cef4c71bb5e2891193f6c8965a3e47'
+        'SKIP')
+validpgpkeys=('986FA7E80256D3D16F30FB7A01380DF54FD09D02') # Frank Lanitz <frank at geany.org>
+
+prepare() {
+  cd $pkgname-$pkgver
+  autoreconf -fi
+
+  # don't redefine bool
+  sed -i 's/typedef unsigned int bool/#include <stdbool.h>/g' \
+    pretty-printer/src/PrettyPrinter.h
+}
+
+build() {
+  cd $pkgname-$pkgver
+  export CFLAGS+=' -w'
+  export PYTHON=/usr/bin/python
+  ./configure --prefix=/usr --libexecdir=/usr/lib
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  make -C $pkgname-$pkgver DESTDIR="$pkgdir" install
+}
+
+# getver: plugins.geany.org/downloads.html