[arch-commits] Commit in fluidsynth/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[David Runge]

    Date: Sunday, November 21, 2021 @ 20:31:05
  Author: dvzrv
Revision: 428767

archrelease: copy trunk to staging-x86_64

Added:
  fluidsynth/repos/staging-x86_64/
  fluidsynth/repos/staging-x86_64/PKGBUILD
    (from rev 428766, fluidsynth/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: fluidsynth/repos/staging-x86_64/PKGBUILD (from rev 428766, fluidsynth/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2021-11-21 20:31:05 UTC (rev 428767)
@@ -0,0 +1,54 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Ray Rashif <schiv at archlinux.org>
+# Contributor: damir <damir at archlinux.org>
+
+pkgname=fluidsynth
+pkgver=2.2.4
+pkgrel=1
+pkgdesc="A real-time software synthesizer based on the SoundFont 2 specifications"
+arch=(x86_64)
+url="https://www.fluidsynth.org/"
+license=(LGPL2.1)
+groups=(pro-audio)
+depends=(glibc sdl2)
+makedepends=(alsa-lib cmake dbus doxygen glib2 jack ladspa libinstpatch
+libpulse libsndfile portaudio readline systemd-libs)
+provides=(libfluidsynth.so soundfont-synthesizer)
+backup=("etc/conf.d/$pkgname")
+source=("$pkgname-$pkgver.tar.gz::https://github.com/${pkgname}/${pkgname}/archive/v$pkgver.tar.gz")
+sha512sums=('46c3f0759cc011f34e5ba80684df4e8b593315d564da2341aaea14a5f0ba9cf732933f6ebc8712506f194b044a8e2b198b9e50879ff4221e6a9ab8051e79b48f')
+b2sums=('28a2a8048ad3f652afd424358b1b268d42672eb8fba0bdb30c72c06041617844fb5b90bc922e905d80ca2818eac03e9e5ce7f9a57b4cf68a43f60ed4bfddcd49')
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  cmake -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_BUILD_TYPE=None \
+        -DFLUID_DAEMON_ENV_FILE=/etc/conf.d/fluidsynth \
+        -Denable-ladspa=ON \
+        -Denable-portaudio=ON \
+        -DLIB_SUFFIX="" \
+        -Wno-dev \
+        -B build \
+        -S .
+  make -C build VERBOSE=1
+}
+
+check() {
+  cd "${pkgname}-${pkgver}"
+  make -C build -k check
+}
+
+package() {
+  depends+=(libasound.so libdbus-1.so libglib-2.0.so libgmodule-2.0.so
+  libgobject-2.0.so libinstpatch-1.0.so libjack.so libportaudio.so
+  libpulse-simple.so libreadline.so libsndfile.so libsystemd.so)
+
+  cd "${pkgname}-${pkgver}"
+  make -C build DESTDIR="$pkgdir" install
+  # systemd user unit
+  install -vDm 644 "build/${pkgname}.service" -t "$pkgdir/usr/lib/systemd/user/"
+  # system-wide configuration file
+  install -vDm 644 "build/${pkgname}.conf" "${pkgdir}/etc/conf.d/${pkgname}"
+  # docs
+  install -vDm 644 {AUTHORS,ChangeLog,{CONTRIBUTING,README}.md,THANKS,TODO} -t "${pkgdir}/usr/share/doc/${pkgname}"
+}