[arch-commits] Commit in harfbuzz/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Felix Yan]

    Date: Sunday, November 21, 2021 @ 23:03:26
  Author: felixonmars
Revision: 428831

archrelease: copy trunk to staging-x86_64

Added:
  harfbuzz/repos/staging-x86_64/
  harfbuzz/repos/staging-x86_64/PKGBUILD
    (from rev 428830, harfbuzz/trunk/PKGBUILD)

----------+
 PKGBUILD |   77 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 77 insertions(+)

Copied: harfbuzz/repos/staging-x86_64/PKGBUILD (from rev 428830, harfbuzz/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2021-11-21 23:03:26 UTC (rev 428831)
@@ -0,0 +1,77 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=harfbuzz
+pkgname=(harfbuzz harfbuzz-icu)
+pkgver=3.1.1
+pkgrel=2
+pkgdesc="OpenType text shaping engine"
+url="https://www.freedesktop.org/wiki/Software/HarfBuzz"
+arch=(x86_64)
+license=(MIT)
+makedepends=(glib2 freetype2 graphite cairo icu gobject-introspection gtk-doc
+             ragel git python meson chafa)
+checkdepends=(python-fonttools python-setuptools)
+_commit=cd5c6cd0419ac5e4de975d6c476fb760bf06d2ce  # tags/3.1.1^0
+source=("git+https://github.com/harfbuzz/harfbuzz#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd harfbuzz
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd harfbuzz
+}
+
+build() {
+  arch-meson harfbuzz build \
+    -D graphite2=enabled
+  meson compile -C build
+}
+
+check() {
+  mkdir -p tmp
+  TMPDIR="$PWD/tmp" meson test -C build --print-errorlogs
+  rm -r tmp
+}
+
+_pick() {
+  local p="$1" f d; shift
+  for f; do
+    d="$srcdir/$p/${f#$pkgdir/}"
+    mkdir -p "$(dirname "$d")"
+    mv "$f" "$d"
+    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+  done
+}
+
+package_harfbuzz() {
+  depends=(glib2 freetype2 graphite libglib-2.0.so libfreetype.so
+           libgobject-2.0.so)
+  provides=(libharfbuzz.so libharfbuzz-subset.so libharfbuzz-gobject.so)
+  optdepends=('cairo: hb-view program'
+              'chafa: hb-view program')
+
+  meson install -C build --destdir "$pkgdir"
+
+  ( cd "$pkgdir"
+
+    _pick hb-icu usr/lib/libharfbuzz-icu*
+    _pick hb-icu usr/lib/pkgconfig/harfbuzz-icu.pc
+    _pick hb-icu usr/include/harfbuzz/hb-icu.h
+  )
+
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 harfbuzz/COPYING
+}
+
+package_harfbuzz-icu() {
+  pkgdesc+=" - ICU integration"
+  depends=("harfbuzz=$pkgver-$pkgrel" libicuuc.so libharfbuzz.so)
+  provides=(libharfbuzz-icu.so)
+
+  mv hb-icu/* "$pkgdir"
+
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 harfbuzz/COPYING
+}