[arch-commits] Commit in tracker3/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Felix Yan]

    Date: Sunday, November 21, 2021 @ 23:07:11
  Author: felixonmars
Revision: 428837

archrelease: copy trunk to staging-x86_64

Added:
  tracker3/repos/staging-x86_64/
  tracker3/repos/staging-x86_64/PKGBUILD
    (from rev 428836, tracker3/trunk/PKGBUILD)

----------+
 PKGBUILD |   65 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)

Copied: tracker3/repos/staging-x86_64/PKGBUILD (from rev 428836, tracker3/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2021-11-21 23:07:11 UTC (rev 428837)
@@ -0,0 +1,65 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Alexander Fehr <pizzapunk gmail com>
+
+pkgbase=tracker3
+pkgname=(tracker3 tracker3-docs)
+pkgver=3.2.1
+pkgrel=2
+pkgdesc="Desktop-neutral user information store, search tool and indexer"
+url="https://wiki.gnome.org/Projects/Tracker"
+arch=(x86_64)
+license=(GPL)
+depends=(sqlite icu glib2 libffi util-linux libstemmer libseccomp json-glib
+         libsoup3)
+makedepends=(gobject-introspection vala git hotdoc bash-completion meson
+             asciidoc systemd libsoup python-gobject python-dbus python-tappy)
+_commit=bcf1347a9eea300d11c95a78f8f74f38131bb560  # tags/3.2.1^0
+source=("git+https://gitlab.gnome.org/GNOME/tracker.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd tracker
+  git describe --tags | sed 's/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd tracker
+}
+
+build() {
+  arch-meson tracker build -D tests_tap_protocol=true
+  meson compile -C build
+}
+
+check() {
+  dbus-run-session meson test -C build --print-errorlogs -t 3
+}
+
+_pick() {
+  local p="$1" f d; shift
+  for f; do
+    d="$srcdir/$p/${f#$pkgdir/}"
+    mkdir -p "$(dirname "$d")"
+    mv "$f" "$d"
+    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+  done
+}
+
+package_tracker3() {
+  optdepends=('libsoup: Alternative remoting backend')
+  provides=(libtracker-sparql-3.0.so)
+
+  meson install -C build --destdir "$pkgdir"
+
+  cd "$pkgdir"
+  _pick docs usr/share/{devhelp,doc}
+}
+
+package_tracker3-docs() {
+  pkgdesc+=" (documentation)"
+  depends=()
+  mv docs/* "$pkgdir"
+}
+
+# vim:set sw=2 et: