[arch-commits] Commit in sile/repos (2 files)

[Felix Yan]

    Date: Monday, November 22, 2021 @ 00:09:00
  Author: felixonmars
Revision: 1054101

archrelease: copy trunk to community-staging-x86_64

Added:
  sile/repos/community-staging-x86_64/
  sile/repos/community-staging-x86_64/PKGBUILD
    (from rev 1054100, sile/trunk/PKGBUILD)

----------+
 PKGBUILD |   68 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)

Copied: sile/repos/community-staging-x86_64/PKGBUILD (from rev 1054100, sile/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-22 00:09:00 UTC (rev 1054101)
@@ -0,0 +1,68 @@
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Adrián Pérez de Castro <aperez at igalia.com>
+
+pkgname=sile
+pkgdesc='Modern typesetting system inspired by TeX'
+pkgver=0.12.0
+pkgrel=5
+arch=(x86_64)
+url=https://www.sile-typesetter.org
+license=(MIT)
+_luadeps=(bit32
+          cassowary
+          cliargs
+          cosmo
+          expat
+          filesystem
+          linenoise
+          lpeg
+          luaepnf
+          luarepl
+          luautf8
+          penlight
+          sec
+          socket
+          stdlib
+          vstruct
+          zlib)
+depends=(glibc
+         fontconfig
+         freetype2
+         harfbuzz
+         gentium-plus-font
+         git
+         icu
+         libpng # this goes with libtexpdf if ever split out to a library package
+         lua
+         "${_luadeps[@]/#/lua-}"
+         zlib)
+depends+=(libfreetype.so
+          libharfbuzz.so
+          libicudata.so
+          libicui18n.so
+          libicuio.so
+          libicuuc.so)
+optdepends=('libertinus-font: math package default font')
+checkdepends=(poppler)
+provides=(libtexpdf.so)
+_archive="$pkgname-$pkgver"
+source=("https://github.com/sile-typesetter/sile/releases/download/v$pkgver/$_archive.tar.xz")
+sha256sums=('c983a2b32d171ba392191eb29de2c3b433452d6cb514f270b17a7b3889fb6de6')
+
+build () {
+	cd "$_archive"
+	./configure \
+		--prefix /usr \
+		--with-system-luarocks
+	make all
+}
+
+check () {
+	cd "$_archive"
+	make check
+}
+
+package () {
+	cd "$_archive"
+	make install DESTDIR="$pkgdir"
+}