[arch-commits] Commit in geary/repos (2 files)

[Evangelos Foutras]

    Date: Monday, November 22, 2021 @ 00:11:22
  Author: foutrelis
Revision: 1054109

archrelease: copy trunk to community-staging-x86_64

Added:
  geary/repos/community-staging-x86_64/
  geary/repos/community-staging-x86_64/PKGBUILD
    (from rev 1054108, geary/trunk/PKGBUILD)

----------+
 PKGBUILD |   71 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 71 insertions(+)

Copied: geary/repos/community-staging-x86_64/PKGBUILD (from rev 1054108, geary/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-22 00:11:22 UTC (rev 1054109)
@@ -0,0 +1,71 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: sebikul <sebikul at gmail.com>
+# Contributor: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+
+pkgname=geary
+pkgver=40.0
+pkgrel=5
+epoch=1
+pkgdesc='A lightweight email client for the GNOME desktop'
+arch=(x86_64)
+url=https://wiki.gnome.org/Apps/Geary
+license=(GPL3)
+groups=(gnome-extra)
+depends=(
+  cairo
+  enchant
+  folks
+  gcr
+  gdk-pixbuf2
+  glib2
+  gmime3
+  gnome-online-accounts
+  gsound
+  gspell
+  gtk3
+  iso-codes
+  libcanberra
+  libgee
+  libhandy
+  libnotify
+  libpeas
+  libsecret
+  libsoup
+  libstemmer
+  libxml2
+  libytnef
+  org.freedesktop.secrets
+  pango
+  sqlite
+  webkit2gtk
+)
+makedepends=(
+  appstream-glib
+  cmake
+  git
+  gobject-introspection
+  meson
+  vala
+  yelp-tools
+)
+_tag=375f741026c8aa9f1ff41ce912f5c08d7d3cad15
+source=(git+https://gitlab.gnome.org/GNOME/geary.git?signed#tag=${_tag})
+validpgpkeys=(3A2EF7F138557A145F2866E99FAB18747A8FC649) # Michael James Gratton <mike at vee.net>
+sha256sums=(SKIP)
+
+pkgver() {
+  cd geary
+  git describe --tags | sed 's/^gnome-//g'
+}
+
+build() {
+  arch-meson geary build \
+    -Dprofile=release
+  meson compile -C build
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+}
+
+# vim: ts=2 sw=2 et: