[arch-commits] Commit in ncmpcpp/repos (2 files)

[Felix Yan]

    Date: Monday, November 22, 2021 @ 00:13:07
  Author: felixonmars
Revision: 1054115

archrelease: copy trunk to community-staging-x86_64

Added:
  ncmpcpp/repos/community-staging-x86_64/
  ncmpcpp/repos/community-staging-x86_64/PKGBUILD
    (from rev 1054114, ncmpcpp/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: ncmpcpp/repos/community-staging-x86_64/PKGBUILD (from rev 1054114, ncmpcpp/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-22 00:13:07 UTC (rev 1054115)
@@ -0,0 +1,58 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: graysky <graysky AT archlinux DOT us>
+# Contributor: Mateusz Herych <heniekk at gmail.com>
+# Contributor: Army <uli[dot]armbruster[at]gmail[dot]com>
+
+pkgname=ncmpcpp
+pkgver=0.9.2
+pkgrel=4
+pkgdesc='Almost exact clone of ncmpc with some new features'
+url='https://ncmpcpp.rybczak.net/'
+arch=('x86_64')
+license=('GPL')
+depends=('curl' 'libcurl.so' 'libmpdclient' 'libmpdclient.so' 'fftw' 'libfftw3.so' 'boost-libs'
+         'libboost_filesystem.so' 'libboost_locale.so' 'libboost_program_options.so'
+         'libboost_regex.so' 'libboost_thread.so' 'icu' 'libicui18n.so' 'libicuuc.so'
+         'glibc' 'gcc-libs' 'ncurses' 'libncursesw.so' 'readline' 'libreadline.so' 'taglib')
+makedepends=('boost')
+source=(https://rybczak.net/ncmpcpp/stable/${pkgname}-${pkgver}.tar.bz2)
+sha512sums=('bbcb3b50233e363412af3c1cf1c0118122733dc376759cd35dee79950f42e098a0402ff670684df91847b990b26022630c9a71192e462bd46e70628e31489742')
+b2sums=('160597493b93bac790b8619881e8a1fcf0efce4a538e35f54f31b06f3ed66691f02b37198cca46b475b7296aebbc864cb62a4398c60bd1e43907f9907a9bc118')
+
+prepare() {
+  cd ${pkgname}-${pkgver}
+  autoreconf -fiv
+  sed -e 's/CXXFLAGS=/CXXFLAGS+=/' \
+      -e 's/CPPFLAGS=/CPPFLAGS+=/' \
+      -e 's/LDFLAGS=/LDFLAGS+=/' \
+      -i extras/Makefile
+}
+
+build() {
+  cd ${pkgname}-${pkgver}
+
+  # http://site.icu-project.org/download/61#TOC-Migration-Issues
+  export CPPFLAGS+=' -DU_USING_ICU_NAMESPACE=1'
+
+  # Work around deprecated TagLib::String::null from TagLib 1.12
+  CXXFLAGS+=' -Wno-error=deprecated-declarations'
+
+  BOOST_LIB_SUFFIX='' ./configure \
+    --prefix=/usr \
+    --enable-clock \
+    --enable-outputs \
+    --enable-visualizer \
+    --with-fftw \
+    --with-taglib
+  make
+  make -C extras
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  make DESTDIR="${pkgdir}" install
+  install -Dm 755 extras/artist_to_albumartist -t "${pkgdir}/usr/bin"
+}
+
+# vim: ts=2 sw=2 et: