[arch-commits] Commit in tracker3-miners/repos (2 files)

[Felix Yan]

    Date: Monday, November 22, 2021 @ 00:55:28
  Author: felixonmars
Revision: 428877

archrelease: copy trunk to staging-x86_64

Added:
  tracker3-miners/repos/staging-x86_64/
  tracker3-miners/repos/staging-x86_64/PKGBUILD
    (from rev 428876, tracker3-miners/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: tracker3-miners/repos/staging-x86_64/PKGBUILD (from rev 428876, tracker3-miners/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2021-11-22 00:55:28 UTC (rev 428877)
@@ -0,0 +1,44 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+
+pkgname=tracker3-miners
+pkgver=3.2.1
+pkgrel=2
+pkgdesc="Collection of data extractors for Tracker/Nepomuk"
+url="https://wiki.gnome.org/Projects/Tracker"
+arch=(x86_64)
+license=(GPL)
+depends=(tracker3 gst-plugins-base-libs exempi libexif libcue libgrss libgsf
+         libgxps libiptcdata libosinfo poppler-glib totem-plparser giflib
+         libgexiv2 gupnp-dlna upower libseccomp libnm)
+makedepends=(git meson vala asciidoc)
+checkdepends=(python-gobject python-tappy gst-plugins-good gst-plugins-base
+              gst-libav)
+groups=(gnome)
+_commit=1e1a9e701faae73148fc05613b7e237715ad0cc9  # tags/3.2.1^0
+source=("git+https://gitlab.gnome.org/GNOME/tracker-miners.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd tracker-miners
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd tracker-miners
+}
+
+build() {
+  arch-meson tracker-miners build -D tests_tap_protocol=true
+  meson compile -C build
+}
+
+check() {
+  # Intermittent test failures: https://gitlab.gnome.org/GNOME/tracker-miners/-/issues/79
+  dbus-run-session meson test -C build --print-errorlogs -t 3 || :
+}
+
+package() {
+  depends+=(libtracker-sparql-3.0.so)
+
+  meson install -C build --destdir "$pkgdir"
+}