[arch-commits] Commit in openvdb/repos (2 files)

[Antonio Rojas]

    Date: Wednesday, November 24, 2021 @ 07:38:53
  Author: arojas
Revision: 1054613

archrelease: copy trunk to community-staging-x86_64

Added:
  openvdb/repos/community-staging-x86_64/
  openvdb/repos/community-staging-x86_64/PKGBUILD
    (from rev 1054612, openvdb/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: openvdb/repos/community-staging-x86_64/PKGBUILD (from rev 1054612, openvdb/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-24 07:38:53 UTC (rev 1054613)
@@ -0,0 +1,42 @@
+# Maintainer : Sven-Hendrik Haase <svenstaro at archlinux.org>
+pkgname=openvdb
+pkgver=9.0.0
+pkgrel=3
+pkgdesc='A large suite of tools for the efficient storage and manipulation of sparse volumetric data discretized on three-dimensional grids'
+url='https://github.com/dreamworksanimation/openvdb'
+arch=('x86_64')
+license=('MPL')
+depends=('boost-libs' 'intel-tbb' 'zlib' 'jemalloc' 'blosc' 'log4cplus')
+makedepends=('doxygen' 'boost' 'cmake' 'mesa' 'cppunit' 'glfw-x11' 'glu' 'python' 'python-numpy' 'ninja')
+optdepends=('glfw: for tools'
+            'glu: for tools'
+            'python-numpy: python module')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/dreamworksanimation/openvdb/archive/v${pkgver}.tar.gz")
+sha512sums=('1410b7b04b03fb09d6775ebe7b95e7c0a484d5f29c84203530ed30ccb7c061470be1abb93189010617342e57f3fecdd66a115c6d222024e68e2384a7fb196194')
+
+build() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+
+  cmake \
+    -Bbuild \
+    -GNinja \
+    -DUSE_NUMPY=ON \
+    -DUSE_LOG4CPLUS=ON \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DOPENVDB_BUILD_PYTHON_MODULE=ON \
+    -DOPENVDB_BUILD_DOCS=ON \
+    -DOPENVDB_BUILD_UNITTESTS=OFF
+
+  ninja -C build
+}
+
+package() {
+  cd "${srcdir}/${pkgname}-${pkgver}/build"
+
+  DESTDIR="${pkgdir}" ninja install
+  # Try to workaround FS#72653 for now
+  mkdir -p "${pkgdir}"/usr/share/cmake-3.22/Modules/
+  ln -s "${pkgdir}"/usr/lib/cmake/OpenVDB/FindOpenVDB.cmake "${pkgdir}"/usr/share/cmake-3.22/Modules/FindOpenVDB.cmake
+}
+
+# vim:set sw=2 sts=2 et: