[arch-commits] Commit in nginx-mod-headers-more/repos (2 files)

[Giancarlo Razzolini]

    Date: Sunday, November 28, 2021 @ 19:45:47
  Author: grazzolini
Revision: 1055394

archrelease: copy trunk to community-testing-x86_64

Added:
  nginx-mod-headers-more/repos/community-testing-x86_64/
  nginx-mod-headers-more/repos/community-testing-x86_64/PKGBUILD
    (from rev 1055392, nginx-mod-headers-more/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: nginx-mod-headers-more/repos/community-testing-x86_64/PKGBUILD (from rev 1055392, nginx-mod-headers-more/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2021-11-28 19:45:47 UTC (rev 1055394)
@@ -0,0 +1,39 @@
+# Maintainer: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+
+pkgname=nginx-mod-headers-more
+pkgver=0.33
+pkgrel=10
+
+_modname="${pkgname#nginx-mod-}"
+_nginxver=1.20.1
+
+pkgdesc="Nginx module to set and clear input and output headers"
+arch=('x86_64')
+depends=("nginx=$_nginxver")
+url="https://github.com/openresty/headers-more-nginx-module"
+license=('BSD')
+
+source=(
+	https://nginx.org/download/nginx-$_nginxver.tar.gz{,.asc}
+	https://github.com/openresty/$_modname-nginx-module/archive/v$pkgver/$_modname-$pkgver.tar.gz
+)
+validpgpkeys=(B0F4253373F8F6F510D42178520A9993A1C052F8) # Maxim Dounin <mdounin at mdounin.ru>
+sha256sums=('e462e11533d5c30baa05df7652160ff5979591d291736cfa5edb9fd2edb48c49'
+            'SKIP'
+            'a3dcbab117a9c103bc1ea5200fc00a7b7d2af97ff7fd525f16f8ac2632e30fbf')
+
+build() {
+	cd "$srcdir"/nginx-$_nginxver
+	./configure --with-compat --add-dynamic-module=../$_modname-nginx-module-$pkgver
+	make modules
+}
+
+package() {
+	cd "$srcdir"/nginx-$_nginxver/objs
+	for mod in *.so; do
+		install -Dm755 $mod "$pkgdir"/usr/lib/nginx/modules/$mod
+	done
+
+	install -Dm644 "$srcdir"/$_modname-nginx-module-$pkgver/README.markdown \
+	               "$pkgdir"/usr/share/licenses/$pkgname/README.markdown
+}