[arch-commits] Commit in pahole/repos (3 files)

[Felix Yan]

    Date: Monday, November 29, 2021 @ 22:19:28
  Author: felixonmars
Revision: 429509

archrelease: copy trunk to staging-x86_64

Added:
  pahole/repos/staging-x86_64/
  pahole/repos/staging-x86_64/PKGBUILD
    (from rev 429508, pahole/trunk/PKGBUILD)
  pahole/repos/staging-x86_64/python.diff
    (from rev 429508, pahole/trunk/python.diff)

-------------+
 PKGBUILD    |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 python.diff |   13 +++++++++++++
 2 files changed, 65 insertions(+)

Copied: pahole/repos/staging-x86_64/PKGBUILD (from rev 429508, pahole/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2021-11-29 22:19:28 UTC (rev 429509)
@@ -0,0 +1,52 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+
+pkgname=pahole
+pkgver=1.22
+pkgrel=2
+pkgdesc="Pahole and other DWARF utils"
+url="https://git.kernel.org/pub/scm/devel/pahole/pahole.git"
+arch=(x86_64)
+license=(GPL2)
+depends=(libelf python)
+makedepends=(git cmake ninja)
+provides=(libdwarves{,_emit,_reorganize}.so)
+_commit=f02af2553ea58ae1186226af0d0ec835a248358f  # tags/v1.22^0
+source=("git+https://git.kernel.org/pub/scm/devel/pahole/pahole.git#commit=$_commit"
+        "git+https://github.com/libbpf/libbpf"
+        python.diff)
+sha256sums=('SKIP'
+            'SKIP'
+            '61f232298d59cbcd5e3c863e3f6866b45b7224d5c649dfb7737196233df034f1')
+
+pkgver() {
+  cd pahole
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+  cd pahole
+
+  # https://bugs.archlinux.org/task/70013
+  git apply -3 ../python.diff
+
+  git submodule init
+  git submodule set-url lib/bpf "$srcdir/libbpf"
+  git submodule update
+}
+
+build() {
+  cmake -S pahole -B build -G Ninja \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=None \
+    -D__LIB=lib
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+
+  python -m compileall -d / "$pkgdir"
+  python -O -m compileall -d / "$pkgdir"
+}
+
+# vim:set sw=2 et:

Copied: pahole/repos/staging-x86_64/python.diff (from rev 429508, pahole/trunk/python.diff)
===================================================================
--- staging-x86_64/python.diff	                        (rev 0)
+++ staging-x86_64/python.diff	2021-11-29 22:19:28 UTC (rev 429509)
@@ -0,0 +1,13 @@
+diff --git i/CMakeLists.txt w/CMakeLists.txt
+index 4140574..4bfe743 100644
+--- i/CMakeLists.txt
++++ w/CMakeLists.txt
+@@ -187,6 +187,7 @@ install(FILES dwarves.h dwarves_emit.h dwarves_reorganize.h
+ install(FILES man-pages/pahole.1 DESTINATION ${CMAKE_INSTALL_PREFIX}/share/man/man1/)
+ install(PROGRAMS ostra/ostra-cg DESTINATION ${CMAKE_INSTALL_PREFIX}/bin)
+ install(PROGRAMS btfdiff fullcircle DESTINATION ${CMAKE_INSTALL_PREFIX}/bin)
+-install(FILES ostra/python/ostra.py DESTINATION ${CMAKE_INSTALL_PREFIX}/share/dwarves/runtime/python)
++find_package(Python3)
++install(FILES ostra/python/ostra.py DESTINATION ${Python3_SITELIB})
+ install(FILES lib/Makefile lib/ctracer_relay.c lib/ctracer_relay.h lib/linux.blacklist.cu
+ 	DESTINATION ${CMAKE_INSTALL_PREFIX}/share/dwarves/runtime)