[arch-commits] Commit in htop/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Christian Hesse]

    Date: Tuesday, November 30, 2021 @ 07:21:23
  Author: eworm
Revision: 429531

archrelease: copy trunk to testing-x86_64

Added:
  htop/repos/testing-x86_64/
  htop/repos/testing-x86_64/PKGBUILD
    (from rev 429530, htop/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: htop/repos/testing-x86_64/PKGBUILD (from rev 429530, htop/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2021-11-30 07:21:23 UTC (rev 429531)
@@ -0,0 +1,50 @@
+# Maintainer: Christian Hesse <mail at eworm.de>
+# Maintainer: Angel Velasquez <angvp at archlinux.org>
+# Contributor: Eric Belanger <eric at archlinux.org>
+# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
+
+pkgname=htop
+_tag='efd29542b1aebfc53f488bf2f992b6d3d7ff3252' # git rev-parse ${pkgver}
+pkgver=3.1.2
+pkgrel=1
+pkgdesc='Interactive process viewer'
+arch=('x86_64')
+url='https://htop.dev/'
+license=('GPL')
+depends=('libcap' 'libcap.so' 'libnl' 'ncurses' 'libncursesw.so')
+makedepends=('git' 'lm_sensors')
+optdepends=('lm_sensors: show cpu temperatures'
+            'lsof: show files opened by a process'
+            'strace: attach to a running process')
+options=('!emptydirs')
+validpgpkeys=('F7ABE8761E6FE68638E6283AFE0842EE36DD8C0C'  # Nathan Scott <nathans at debian.org>
+              '0D316B6ABE022C7798D0324BF1D35CB9E8E12EAD') # Benny Baumann <BenBE at geshi.org>
+source=("git+https://github.com/htop-dev/htop.git#tag=${_tag}?signed")
+sha256sums=('SKIP')
+
+prepare() {
+  cd "${pkgname}"
+
+  autoreconf -fi
+}
+
+build() {
+  cd "${pkgname}"
+
+  ./configure \
+      --prefix=/usr \
+      --sysconfdir=/etc \
+      --enable-cgroup \
+      --enable-delayacct \
+      --enable-openvz \
+      --enable-unicode \
+      --enable-vserver
+
+  make
+}
+
+package() {
+  cd "${pkgname}"
+
+  make DESTDIR="${pkgdir}" install
+}