[arch-commits] Commit in python-typing_extensions/repos (2 files)

[Evangelos Foutras]

    Date: Tuesday, November 30, 2021 @ 20:17:57
  Author: foutrelis
Revision: 1057938

archrelease: copy trunk to community-staging-any

Added:
  python-typing_extensions/repos/community-staging-any/
  python-typing_extensions/repos/community-staging-any/PKGBUILD
    (from rev 1057935, python-typing_extensions/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: python-typing_extensions/repos/community-staging-any/PKGBUILD (from rev 1057935, python-typing_extensions/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2021-11-30 20:17:57 UTC (rev 1057938)
@@ -0,0 +1,54 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Michael Yeatts <mwyeatts at gmail.com>
+
+pkgname=python-typing_extensions
+pkgver=3.10.0.2
+pkgrel=3
+pkgdesc='Backported and Experimental Type Hints for Python 3.5+'
+arch=(any)
+url=https://github.com/python/typing/tree/master/typing_extensions
+license=(custom)
+depends=(python)
+makedepends=(
+  git
+  python-setuptools
+)
+checkdepends=(python-tests)
+provides=(python-typing-extensions)
+conflicts=(python-typing-extensions)
+_tag=7552efe8b5f96f0e63f8e77711a4cf03cae92921
+source=(git+https://github.com/python/typing.git#tag=${_tag})
+sha256sums=(SKIP)
+
+pkgver() {
+  cd typing
+
+  git describe --tags
+}
+
+prepare() {
+  sed 's/3.7.4.2/3.7.4.3/g' -i typing/typing_extensions/setup.py
+}
+
+build() {
+  cd typing/typing_extensions
+
+  python setup.py build
+}
+
+check() {
+  cd typing/typing_extensions
+
+  python -m venv --system-site-packages test-env
+  test-env/bin/python setup.py install --optimize=1 --skip-build
+  test-env/bin/python src_py3/test_typing_extensions.py
+}
+
+package() {
+  cd typing/typing_extensions
+
+  python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+  install -Dm 644 LICENSE -t "${pkgdir}"/usr/share/licenses/python-typing_extensions/
+}
+
+# vim: ts=2 sw=2 et: