[arch-commits] Commit in python-mpi4py/repos (2 files)

[Evangelos Foutras]

    Date: Tuesday, November 30, 2021 @ 20:23:17
  Author: foutrelis
Revision: 1058167

archrelease: copy trunk to community-staging-x86_64

Added:
  python-mpi4py/repos/community-staging-x86_64/
  python-mpi4py/repos/community-staging-x86_64/PKGBUILD
    (from rev 1058164, python-mpi4py/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: python-mpi4py/repos/community-staging-x86_64/PKGBUILD (from rev 1058164, python-mpi4py/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-30 20:23:17 UTC (rev 1058167)
@@ -0,0 +1,41 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Anatol Pomozov
+# Contributor: Tim Hütz <tim at huetz.biz>
+# Contributor: Stéphane Gaudreault <stephane at archlinux.org>
+# Contributor: Sebastien Binet <binet at cern.ch>
+
+_pkg=mpi4py
+pkgname=python-${_pkg}
+pkgver=3.1.1
+pkgrel=2
+pkgdesc="Python bindings for the Message Passing Interface (MPI) standard"
+arch=(x86_64)
+url="https://bitbucket.org/mpi4py/mpi4py"
+license=(BSD)
+depends=(python openmpi)
+makedepends=(python-setuptools cython)
+checkdepends=(inetutils)
+source=(https://files.pythonhosted.org/packages/source/${_pkg::1}/${_pkg}/${_pkg}-${pkgver}.tar.gz)
+sha256sums=('e11f8587a3b93bb24c8526addec664b586b965d83c0882b884c14dc3fd6b9f5c')
+
+build() {
+    cd ${_pkg}-${pkgver}
+    python setup.py build
+}
+
+check() {
+    # This is required starting with OpenMPI 3.0 when trying to run more
+    # processes than the number of available cores
+    export OMPI_MCA_rmaps_base_oversubscribe=yes
+    # We don’t have CUDA by default
+    export OMPI_MCA_opal_warn_on_missing_libcuda=0
+
+    cd ${_pkg}-${pkgver}
+    python setup.py test
+}
+
+package() {
+    cd ${_pkg}-${pkgver}
+    python setup.py install --root="${pkgdir}" --skip-build --optimize=1
+    install -Dm644 LICENSE.rst -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}