[arch-commits] Commit in flatbuffers/repos (2 files)

[Evangelos Foutras]

    Date: Tuesday, November 30, 2021 @ 20:19:39
  Author: foutrelis
Revision: 1058006

archrelease: copy trunk to community-staging-x86_64

Added:
  flatbuffers/repos/community-staging-x86_64/
  flatbuffers/repos/community-staging-x86_64/PKGBUILD
    (from rev 1058005, flatbuffers/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: flatbuffers/repos/community-staging-x86_64/PKGBUILD (from rev 1058005, flatbuffers/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-30 20:19:39 UTC (rev 1058006)
@@ -0,0 +1,47 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Daichi Shinozaki <dsdseg at gmail.com>
+
+pkgbase=flatbuffers
+pkgname=(flatbuffers python-flatbuffers)
+pkgver=2.0.0
+pkgrel=2
+pkgdesc='An efficient cross platform serialization library for C++, with support for Java, C# and Go'
+arch=(x86_64)
+url='https://google.github.io/flatbuffers/'
+license=(Apache)
+depends=(gcc-libs)
+makedepends=(cmake python-setuptools)
+source=(https://github.com/google/$pkgbase/archive/v$pkgver/$pkgbase-$pkgver.tar.gz)
+sha256sums=('9ddb9031798f4f8754d00fca2f1a68ecf9d0f83dfac7239af1311e4fd9a565c4')
+
+prepare() {
+  sed -i 's/-Werror=/-W/g;s/-Werror//g' $pkgname-$pkgver/CMakeLists.txt
+}
+
+build() {
+  cmake -B build -S $pkgbase-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DFLATBUFFERS_BUILD_FLATLIB=OFF \
+    -DFLATBUFFERS_BUILD_SHAREDLIB=ON
+  cmake --build build
+
+# Python bindings
+  cd $pkgbase-$pkgver/python
+  VERSION=$pkgver python setup.py build
+}
+
+check() {
+  cmake --build build --target test
+}
+
+package_flatbuffers() {
+  DESTDIR="$pkgdir" cmake --install build
+}
+
+package_python-flatbuffers() {
+  pkgdesc='An efficient cross platform serialization library for Python'
+  depends=(python)
+
+  cd $pkgbase-$pkgver/python
+  VERSION=$pkgver python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}