[arch-commits] Commit in python-tqdm/repos (2 files)

[Evangelos Foutras]

    Date: Tuesday, November 30, 2021 @ 21:12:19
  Author: foutrelis
Revision: 1058841

archrelease: copy trunk to community-staging-any

Added:
  python-tqdm/repos/community-staging-any/
  python-tqdm/repos/community-staging-any/PKGBUILD
    (from rev 1058839, python-tqdm/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: python-tqdm/repos/community-staging-any/PKGBUILD (from rev 1058839, python-tqdm/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2021-11-30 21:12:19 UTC (rev 1058841)
@@ -0,0 +1,48 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_pkgname=tqdm
+pkgname=python-$_pkgname
+pkgver=4.62.3
+pkgrel=2
+pkgdesc='Fast, Extensible Progress Meter'
+arch=('any')
+license=('MIT' 'MPL')
+url='https://github.com/tqdm/tqdm'
+depends=('python')
+optdepends=('python-requests: telegram')
+makedepends=('python-setuptools-scm' 'python-toml')
+checkdepends=('python-pytest' 'python-pytest-asyncio' 'python-pytest-timeout' 'python-numpy'
+              'python-pandas' 'python-tensorflow' 'python-rich' 'python-dask' 'tk')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/tqdm/tqdm/archive/v$pkgver.tar.gz")
+sha512sums=('4ee74d89697b726382a50a51c4ed6001014105068dd909e6809b4db408af570e3af3d046cff476017cd5107b26459a0b0e18a80c87b883d5d6a0af23c8d0f8c2')
+
+build() {
+  cd $_pkgname-$pkgver
+
+  export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
+
+  python setup.py build
+}
+
+check() {
+  cd $_pkgname-$pkgver
+
+  export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
+
+  python -m venv --system-site-packages test-env
+
+  test-env/bin/python setup.py install
+  test-env/bin/python -m pytest -k 'not test_dask'
+}
+
+package() {
+  cd $_pkgname-$pkgver
+
+  export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
+
+  python setup.py install --root="$pkgdir" --optimize=1
+
+  install -D -m644 LICENCE "$pkgdir"/usr/share/licenses/$pkgname/LICENCE
+}
+
+# vim:set ts=2 sw=2 et: