[arch-commits] Commit in python-secretstorage/repos (2 files)

[Felix Yan]

    Date: Tuesday, November 30, 2021 @ 21:30:23
  Author: felixonmars
Revision: 1058912

archrelease: copy trunk to community-staging-any

Added:
  python-secretstorage/repos/community-staging-any/
  python-secretstorage/repos/community-staging-any/PKGBUILD
    (from rev 1058911, python-secretstorage/trunk/PKGBUILD)

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Copied: python-secretstorage/repos/community-staging-any/PKGBUILD (from rev 1058911, python-secretstorage/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2021-11-30 21:30:23 UTC (rev 1058912)
@@ -0,0 +1,37 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Filipe Laíns (FFY00) <lains at archlinux.org>
+# Contributor: Patrice Peterson <runiq at archlinux dot us>
+# Contributor: JonnyJD <arch at JonnyJD.net>
+
+pkgname=python-secretstorage
+_pkgname=SecretStorage
+pkgver=3.3.1
+pkgrel=2
+pkgdesc="Securely store passwords and other private data using the SecretService DBus API"
+arch=('any')
+url="https://github.com/mitya57/secretstorage"
+license=('BSD')
+depends=('python-cryptography' 'python-jeepney')
+makedepends=('python-setuptools')
+checkdepends=('org.freedesktop.secrets' 'xorg-server-xvfb')
+source=("https://pypi.io/packages/source/${_pkgname:0:1}/$_pkgname/$_pkgname-$pkgver.tar.gz")
+sha512sums=('5e874d08c9e00626a217db96b131884daf92429a91f690b32f62052747275ad0effbe2b4abe048e67fe7f81df97507f8375408898ff986e6f883b5fdfbf2a76c')
+
+build() {
+  cd $_pkgname-$pkgver
+
+  python setup.py build
+}
+
+check() {
+  cd $_pkgname-$pkgver
+
+  dbus-launch xvfb-run -a python -m unittest discover -s tests || echo "Tests failed"
+}
+
+package() {
+  cd $_pkgname-$pkgver
+
+  python setup.py install --root="$pkgdir" -O1
+  install -Dm 644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}