[arch-commits] Commit in python-alembic/repos (2 files)

[Felix Yan]

    Date: Tuesday, November 30, 2021 @ 21:42:51
  Author: felixonmars
Revision: 1058960

archrelease: copy trunk to community-staging-any

Added:
  python-alembic/repos/community-staging-any/
  python-alembic/repos/community-staging-any/PKGBUILD
    (from rev 1058954, python-alembic/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: python-alembic/repos/community-staging-any/PKGBUILD (from rev 1058954, python-alembic/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2021-11-30 21:42:51 UTC (rev 1058960)
@@ -0,0 +1,45 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: googol <googol at posteo.de>
+# Contributor: Oliver Mangold <o.mangold at gmail dot com>
+
+pkgname=python-alembic
+pkgver=1.7.4
+pkgrel=2
+pkgdesc='Lightweight database migration tool for usage with SQLAlchemy'
+url='https://github.com/sqlalchemy/alembic'
+arch=('any')
+license=('MIT')
+depends=('python' 'python-mako' 'python-sqlalchemy' 'python-editor' 'python-dateutil')
+makedepends=('python-setuptools' 'python-mako' 'python-sqlalchemy' 'python-editor' 'python-dateutil')
+checkdepends=('python-pytest' 'python-mock')
+source=(https://pypi.org/packages/source/a/alembic/alembic-${pkgver}.tar.gz{,.asc})
+sha512sums=('7e3fea729d389c01a4c7756d83d54dacad7ff5b485e80e450da6584f8def14c478e5701bd97290c76894151aada5d4ae2b2cea360c3ff8e48f25a95fa1d19d79'
+            'SKIP')
+b2sums=('1bd11a9dc870dbf861b5c09262dbb0edcb413d6e8f86e6ddcd60d8aceebeb4bfeea9ef7ac6a389c10bded0e9cf478df313c7913ad5995580b88cdf9499e89f18'
+        'SKIP')
+validpgpkeys=('83AF7ACE251C13E6BB7DEFBD330239C1C4DAFEE1') # Michael Bayer <classic at zzzcomputing.com>
+
+prepare() {
+  cd alembic-${pkgver}
+  # do not treat warnings as errors
+  sed 's|-p no:warnings||g' -i setup.cfg
+}
+
+build() {
+  cd alembic-${pkgver}
+  python setup.py build
+}
+
+check() {
+  cd alembic-${pkgver}
+  py.test
+}
+
+package() {
+  cd alembic-${pkgver}
+  python setup.py install --root="${pkgdir}" --prefix=/usr -O1 --skip-build
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -Dm 644 README.rst CHANGES -t "${pkgdir}/usr/share/doc/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: