[arch-commits] Commit in python-websockets/repos (2 files)

[Felix Yan]

    Date: Tuesday, November 30, 2021 @ 21:43:01
  Author: felixonmars
Revision: 1058963

archrelease: copy trunk to community-staging-x86_64

Added:
  python-websockets/repos/community-staging-x86_64/
  python-websockets/repos/community-staging-x86_64/PKGBUILD
    (from rev 1058962, python-websockets/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: python-websockets/repos/community-staging-x86_64/PKGBUILD (from rev 1058962, python-websockets/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-30 21:43:01 UTC (rev 1058963)
@@ -0,0 +1,39 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Sherlock Holo <sherlockya at gmail.com>
+# Contributor: user6553591 <Message on Reddit>
+
+pkgname=python-websockets
+pkgver=9.1
+pkgrel=2
+pkgdesc='Python implementation of the WebSocket Protocol (RFC 6455)'
+url='https://github.com/aaugustin/websockets'
+arch=('x86_64')
+license=('BSD')
+depends=('python')
+makedepends=('python-setuptools' 'python-sphinx' 'python-sphinx-autodoc-typehints' 'python-sphinxcontrib-trio')
+source=(https://github.com/aaugustin/websockets/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha512sums=('ff2907a913ff0b8ced6dda72b6fc6512a2ece3ffded2e2dcb8ff6805de9ad504430cc1871c1f6e02ab8069e7b96b2e7609afaf3c9c25f9271b28e2daa72bd3ac')
+b2sums=('cb3807f01e1a4c22a40bf5150d1e8b21ca786dc5bc4da8f3e6602971f3f7c79b57092f5ddfe3ee52ec00e7fd15f3a992fdbb94b5e26599f2621a7f51434ba6dd')
+
+build() {
+  cd websockets-${pkgver}
+  python setup.py build
+  sphinx-build -b text docs docs/_build/text
+  sphinx-build -b man docs docs/_build/man
+}
+
+check() {
+  cd websockets-${pkgver}
+  python setup.py test
+}
+
+package() {
+  cd websockets-${pkgver}
+  python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+  install -Dm 644 README.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -Dm 644 docs/_build/text/*.txt -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 docs/_build/man/websockets.1 "${pkgdir}/usr/share/man/man1/${pkgname}.1"
+}
+
+# vim: ts=2 sw=2 et: