[arch-commits] Commit in libimobiledevice/repos (2 files)

[Evangelos Foutras]

    Date: Tuesday, November 30, 2021 @ 22:31:27
  Author: foutrelis
Revision: 429854

archrelease: copy trunk to staging-x86_64

Added:
  libimobiledevice/repos/staging-x86_64/
  libimobiledevice/repos/staging-x86_64/PKGBUILD
    (from rev 429853, libimobiledevice/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: libimobiledevice/repos/staging-x86_64/PKGBUILD (from rev 429853, libimobiledevice/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2021-11-30 22:31:27 UTC (rev 429854)
@@ -0,0 +1,48 @@
+# Contributor: Tom Gundersen <teg at jklm.no>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Gabriel Martinez < reitaka at gmail dot com >
+
+pkgname=libimobiledevice
+pkgver=1.3.0
+pkgrel=4
+pkgdesc="Library that talks the protocols to support iPhone and iPod Touch devices on Linux"
+url="https://libimobiledevice.org/"
+arch=('x86_64')
+license=('GPL2' 'LGPL2.1')
+depends=('libusbmuxd' 'usbmuxd' 'gnutls')
+makedepends=('python' 'cython' 'libplist' 'autoconf-archive'
+             'git' 'python-setuptools')
+_commit=15f8652126664e3a4b980e5d1c039b9053ce8566
+source=("git+https://github.com/libimobiledevice/libimobiledevice#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  # Update ac_python_devel.m4 to newer ax_python_devel.m4
+  git cherry-pick -n eea4f1be91
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() (
+  cd $pkgname
+  ./configure --prefix=/usr --disable-openssl
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+)
+
+check() {
+  cd $pkgname
+  make check
+}
+
+package() {
+  cd $pkgname
+  DESTDIR="$pkgdir" make install
+}
+
+# vim:set sw=2 et: