[arch-commits] Commit in python-pylint/repos (2 files)

[Evangelos Foutras]

    Date: Tuesday, November 30, 2021 @ 22:31:36
  Author: foutrelis
Revision: 1059025

archrelease: copy trunk to community-staging-any

Added:
  python-pylint/repos/community-staging-any/
  python-pylint/repos/community-staging-any/PKGBUILD
    (from rev 1059024, python-pylint/trunk/PKGBUILD)

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Copied: python-pylint/repos/community-staging-any/PKGBUILD (from rev 1059024, python-pylint/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2021-11-30 22:31:36 UTC (rev 1059025)
@@ -0,0 +1,56 @@
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Angel Velasquez <angvp at archlinux.org>
+# Contributor: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Stéphane Gaudreault <stephane at archlinux.org>
+# Contributor: Alexander Fehr <pizzapunk gmail com>
+
+_pyname=pylint
+pkgname=python-$_pyname
+pkgver=2.12.1
+pkgrel=2
+pkgdesc='Analyzes Python code looking for bugs and signs of poor quality'
+arch=(any)
+url=https://pylint.org
+license=(GPL)
+_pydeps=(astroid
+         isort
+         mccabe
+         platformdirs
+         toml
+         typing_extensions) # for python<3.10
+depends=(python
+         "${_pydeps[@]/#/python-}")
+makedepends=(python-setuptools
+             python-sphinx)
+checkdepends=(mpdecimal
+              python-pytest
+              python-gitpython)
+optdepends=('graphviz: Enable output formats other than dot or vcg'
+            'tk: Pylint GUI')
+_archive="$_pyname-$pkgver"
+source=("https://github.com/PyCQA/pylint/archive/v$pkgver/$_archive.tar.gz")
+sha256sums=('9fa85a5f0704c8a880762c3e7c938993b2ff619291171acde97127fcb134c02e')
+
+prepare() {
+	cd "$_archive"
+	# Remove overly restrictive dependency pinning that ends up in runtime checks
+	sed -i -e '/>=/{s/>.*//;p}' -e '/python_requires/d' setup.cfg
+}
+
+build() {
+	cd "$_archive"
+	python setup.py build
+	make PYTHONPATH="$PWD/build/lib" -C doc man
+}
+
+check() {
+	cd "$_archive"
+	PYTHONPATH="$PWD/build/lib" pytest \
+		--deselect tests/benchmark/test_baseline_benchmarks.py
+}
+
+package() {
+	cd "$_archive"
+	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+	install -Dm0644 -t "$pkgdir/usr/share/man/man1/" doc/_build/man/*
+}