[arch-commits] Commit in pyqt5/repos (3 files)

Evangelos Foutras foutrelis at gemini.archlinux.org
Tue Nov 30 22:37:35 UTC 2021


    Date: Tuesday, November 30, 2021 @ 22:37:35
  Author: foutrelis
Revision: 429858

archrelease: copy trunk to staging-x86_64

Added:
  pyqt5/repos/staging-x86_64/
  pyqt5/repos/staging-x86_64/PKGBUILD
    (from rev 429857, pyqt5/trunk/PKGBUILD)
  pyqt5/repos/staging-x86_64/restore-sip4-support.patch
    (from rev 429857, pyqt5/trunk/restore-sip4-support.patch)

----------------------------+
 PKGBUILD                   |   67 +++++++++++++++++++++++++++++++++++++++++++
 restore-sip4-support.patch |   12 +++++++
 2 files changed, 79 insertions(+)

Copied: pyqt5/repos/staging-x86_64/PKGBUILD (from rev 429857, pyqt5/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2021-11-30 22:37:35 UTC (rev 429858)
@@ -0,0 +1,67 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Yichao Yu <yyc1992 at gmail.com>
+# Contributor: Douglas Soares de Andrade <douglas at archlinux.org>
+# Contributor: riai <riai at bigfoot.com> Ben <ben at benmazer.net>
+
+pkgbase=pyqt5
+pkgname=('python-pyqt5')
+pkgdesc="A set of Python bindings for the Qt5 toolkit"
+pkgver=5.15.6
+pkgrel=3
+arch=('x86_64')
+url="https://riverbankcomputing.com/software/pyqt/intro"
+license=('GPL')
+groups=(pyqt5)
+depends=('python-pyqt5-sip' 'qt5-base')
+optdepends=('python-opengl: enable OpenGL 3D graphics in PyQt applications'
+            'python-dbus: for python-dbus mainloop support'
+            'qt5-multimedia: QtMultimedia, QtMultimediaWidgets'
+            'qt5-tools: QtHelp, QtDesigner'
+            'qt5-svg: QtSvg'
+            'qt5-webkit: QtWebKit, QtWebKitWidgets'
+            'qt5-xmlpatterns: QtXmlPatterns'
+            'qt5-declarative: QtQml, qmlplugin'
+            'qt5-serialport: QtSerialPort'
+            'qt5-websockets: QtWebSockets'
+            'qt5-connectivity: QtNfc, QtBluetooth'
+            'qt5-x11extras: QtX11Extras'
+            'qt5-remoteobjects: QtRemoteObjects'
+            'qt5-speech: QtTextToSpeech'
+            'qt5-quick3d: QtQuick3D')
+provides=(qt5-python-bindings)
+makedepends=('sip' 'pyqt-builder' 'python-opengl' 'python-dbus'
+             'qt5-connectivity' 'qt5-multimedia' 'qt5-tools' 'qt5-serialport' 'qt5-speech' 'qt5-svg'
+             'qt5-webkit' 'qt5-websockets' 'qt5-x11extras' 'qt5-xmlpatterns' 'qt5-remoteobjects' 'qt5-quick3d')
+conflicts=('pyqt5-common')
+source=("https://pypi.python.org/packages/source/P/PyQt5/PyQt5-$pkgver.tar.gz"
+         restore-sip4-support.patch)
+sha256sums=('80343bcab95ffba619f2ed2467fd828ffeb0a251ad7225be5fc06dcc333af452'
+            'c8881a8dc666e509773f93330615d310f9f040c2167dc9e98843741691395f72')
+
+prepare() {
+  patch -d PyQt5-$pkgver -p1 < restore-sip4-support.patch # https://www.riverbankcomputing.com/pipermail/pyqt/2021-November/044346.html
+}
+
+build() {
+  cd PyQt5-$pkgver
+  sip-build \
+    --confirm-license \
+    --no-make \
+    --api-dir /usr/share/qt/qsci/api/python
+  cd build
+  make
+}
+
+package_python-pyqt5(){
+  cd PyQt5-$pkgver/build
+  make INSTALL_ROOT="$pkgdir" install -j1
+
+  # Remove unused py2 version of uic modules:
+  rm -r "$pkgdir"/usr/lib/python*/site-packages/PyQt5/uic/port_v2
+
+  # compile Python bytecode
+  python -m compileall -d / "$pkgdir"/usr/lib
+  python -O -m compileall -d / "$pkgdir"/usr/lib
+}

Copied: pyqt5/repos/staging-x86_64/restore-sip4-support.patch (from rev 429857, pyqt5/trunk/restore-sip4-support.patch)
===================================================================
--- staging-x86_64/restore-sip4-support.patch	                        (rev 0)
+++ staging-x86_64/restore-sip4-support.patch	2021-11-30 22:37:35 UTC (rev 429858)
@@ -0,0 +1,12 @@
+diff -ru PyQt5-5.15.6.orig/sip/QtCore/QtCoremod.sip PyQt5-5.15.6/sip/QtCore/QtCoremod.sip
+--- PyQt5-5.15.6.orig/sip/QtCore/QtCoremod.sip	2021-11-06 19:41:47.117226645 +0100
++++ PyQt5-5.15.6/sip/QtCore/QtCoremod.sip	2021-11-06 19:42:32.674011854 +0100
+@@ -20,7 +20,7 @@
+ // WARRANTY OF DESIGN, MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
+ 
+ 
+-%Module(name=PyQt5.QtCore, call_super_init=True, default_VirtualErrorHandler=PyQt5, keyword_arguments="Optional", use_limited_api=True, py_ssize_t_clean=True)
++%Module(name=PyQt5.QtCore, call_super_init=True, default_VirtualErrorHandler=PyQt5, keyword_arguments="Optional", use_limited_api=True)
+ 
+ %Timeline {Qt_5_0_0 Qt_5_0_1 Qt_5_0_2 Qt_5_1_0 Qt_5_1_1 Qt_5_2_0 Qt_5_2_1 Qt_5_3_0 Qt_5_3_1 Qt_5_3_2 Qt_5_4_0 Qt_5_4_1 Qt_5_4_2 Qt_5_5_0 Qt_5_5_1 Qt_5_6_0 Qt_5_6_1 Qt_5_6_2 Qt_5_6_3 Qt_5_6_4 Qt_5_6_5 Qt_5_6_6 Qt_5_6_7 Qt_5_6_8 Qt_5_6_9 Qt_5_7_0 Qt_5_7_1 Qt_5_8_0 Qt_5_8_1 Qt_5_9_0 Qt_5_9_1 Qt_5_9_2 Qt_5_9_3 Qt_5_9_4 Qt_5_9_5 Qt_5_9_6 Qt_5_9_7 Qt_5_9_8 Qt_5_9_9 Qt_5_10_0 Qt_5_10_1 Qt_5_11_0 Qt_5_11_1 Qt_5_11_2 Qt_5_11_3 Qt_5_12_0 Qt_5_12_1 Qt_5_12_2 Qt_5_12_3 Qt_5_12_4 Qt_5_13_0 Qt_5_14_0 Qt_5_15_0}
+ 



More information about the arch-commits mailing list