[arch-commits] Commit in pyqt6/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Felix Yan]

    Date: Tuesday, November 30, 2021 @ 22:38:50
  Author: felixonmars
Revision: 429860

archrelease: copy trunk to staging-x86_64

Added:
  pyqt6/repos/staging-x86_64/
  pyqt6/repos/staging-x86_64/PKGBUILD
    (from rev 429859, pyqt6/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: pyqt6/repos/staging-x86_64/PKGBUILD (from rev 429859, pyqt6/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2021-11-30 22:38:50 UTC (rev 429860)
@@ -0,0 +1,49 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+
+pkgbase=pyqt6
+pkgname=python-pyqt6
+pkgdesc='A set of Python bindings for the Qt6 toolkit'
+pkgver=6.2.1
+pkgrel=2
+arch=(x86_64)
+url='https://riverbankcomputing.com/software/pyqt/intro'
+license=(GPL)
+groups=(pyqt6)
+depends=(qt6-base python-pyqt6-sip)
+optdepends=('qt6-tools: QtHelp, QtDesigner bindings'
+            'qt6-svg: QtSvg bindings'
+            'qt6-declarative: QtQml bindings, qmlplugin'
+            'qt6-quick3d: QtQuick3D bindings'
+            'qt6-connectivity: QtBluetooth, QtNfc bindings'
+            'qt6-multimedia: QtMultimedia bindings'
+            'qt6-location: QtPositioning bindings'
+            'qt6-remoteobjects: QtRemoteObjects bindings'
+            'qt6-sensors: QtSensors bindings'
+            'qt6-serialport: QtSerialPort bindings'
+            'qt6-webchannel: QtWebChannel bindings'
+            'qt6-websockets: QtWebSockets bindings'
+            'dbus-python: for python-dbus mainloop support')
+makedepends=(sip pyqt-builder python-opengl dbus-python
+             qt6-tools qt6-svg qt6-declarative qt6-quick3d qt6-shadertools qt6-multimedia qt6-remoteobjects
+             qt6-location qt6-sensors qt6-serialport qt6-webchannel qt6-websockets qt6-connectivity)
+source=(https://pypi.python.org/packages/source/P/PyQt6/PyQt6-$pkgver.tar.gz)
+sha256sums=('d603a5c8effccc9174b3f43834256401a61ea40f2338306ca22fb6a1e870b89c')
+
+build() {
+  cd PyQt6-$pkgver
+  sip-build \
+    --confirm-license \
+    --no-make \
+    --qmake=/usr/bin/qmake6
+  cd build
+  make
+}
+
+package_python-pyqt6(){
+  cd PyQt6-$pkgver/build
+  make INSTALL_ROOT="$pkgdir" install
+
+  # compile Python bytecode
+  python -m compileall -d / "$pkgdir"/usr/lib
+  python -O -m compileall -d / "$pkgdir"/usr/lib
+}