[arch-commits] Commit in python-netcdf4/repos (2 files)

[Evangelos Foutras]

    Date: Friday, October 1, 2021 @ 14:07:10
  Author: foutrelis
Revision: 1026365

archrelease: copy trunk to community-staging-x86_64

Added:
  python-netcdf4/repos/community-staging-x86_64/
  python-netcdf4/repos/community-staging-x86_64/PKGBUILD
    (from rev 1026364, python-netcdf4/trunk/PKGBUILD)

----------+
 PKGBUILD |   34 ++++++++++++++++++++++++++++++++++
 1 file changed, 34 insertions(+)

Copied: python-netcdf4/repos/community-staging-x86_64/PKGBUILD (from rev 1026364, python-netcdf4/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-10-01 14:07:10 UTC (rev 1026365)
@@ -0,0 +1,34 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Spyros Stathopoulos <foucault.online at gmail.com>
+# Contributor: richli <rich at dranek dot com>
+# Contributor: rememberthemer <rememberthemer at _GMAIL_DOT_COM_>
+
+_pkg=netCDF4
+pkgname=python-${_pkg,,}
+pkgver=1.5.7
+pkgrel=2
+pkgdesc="Python/NumPy interface to the netCDF C library"
+arch=(x86_64)
+url="https://unidata.github.io/netcdf4-python"
+license=(MIT)
+depends=(python-numpy python-cftime netcdf)
+makedepends=(cython python-setuptools)
+source=(https://files.pythonhosted.org/packages/source/${_pkg::1}/${_pkg}/${_pkg}-${pkgver}.tar.gz)
+sha256sums=('d145f9c12da29da3922d8b8aafea2a2a89501bcb28a219a46b7b828b57191594')
+
+build() {
+  cd ${_pkg}-${pkgver}
+  USE_NCCONFIG=1 python setup.py build
+}
+
+check() {
+  cd ${_pkg}-${pkgver}/test
+  local python_version=$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')
+  PYTHONPATH="../build/lib.linux-${CARCH}-${python_version}" python -B ./run_all.py
+}
+
+package() {
+  cd ${_pkg}-${pkgver}
+  USE_NCCONFIG=1 python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=2
+  install -Dm644 LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}