[arch-commits] Commit in python-cryptography/repos (2 files)

[Felix Yan]

    Date: Tuesday, October 5, 2021 @ 19:19:22
  Author: felixonmars
Revision: 425155

archrelease: copy trunk to testing-x86_64

Added:
  python-cryptography/repos/testing-x86_64/
  python-cryptography/repos/testing-x86_64/PKGBUILD
    (from rev 425154, python-cryptography/trunk/PKGBUILD)

----------+
 PKGBUILD |   35 +++++++++++++++++++++++++++++++++++
 1 file changed, 35 insertions(+)

Copied: python-cryptography/repos/testing-x86_64/PKGBUILD (from rev 425154, python-cryptography/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2021-10-05 19:19:22 UTC (rev 425155)
@@ -0,0 +1,35 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=python-cryptography
+pkgver=35.0.0
+pkgrel=1
+pkgdesc="A package designed to expose cryptographic recipes and primitives to Python developers"
+arch=('x86_64')
+license=('Apache')
+url="https://pypi.python.org/pypi/cryptography"
+depends=('python-cffi')
+makedepends=('python-setuptools-rust')
+checkdepends=('python-pytest-runner' 'python-pytest-subtests' "python-cryptography-vectors=$pkgver"
+              'python-iso8601' 'python-pretend' 'python-hypothesis' 'python-pytz')
+source=("https://pypi.io/packages/source/c/cryptography/cryptography-$pkgver.tar.gz")
+sha512sums=('447fd81ea82bd5875f14b3dca0fe6c1e8ebe661485252b00c3a19ab91bc0261289fbc59f9a22ba9317e8ba01f7f197c90ca6973f9d87a5d8851eeff2e1168d1d')
+
+prepare() {
+  # https://github.com/pyca/cryptography/pull/5777
+  sed -i '/install_requires/d' cryptography-$pkgver/setup.py
+}
+
+build() {
+  cd cryptography-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd cryptography-$pkgver
+  python setup.py pytest
+}
+
+package() {
+  cd cryptography-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}