[arch-commits] Commit in (5 files)

[Maxime Gauduin]

    Date: Tuesday, October 5, 2021 @ 20:24:11
  Author: alucryd
Revision: 1027784

add emby-theater

Added:
  emby-theater/
  emby-theater/trunk/
  emby-theater/trunk/PKGBUILD
  emby-theater/trunk/emby-theater.desktop
  emby-theater/trunk/emby-theater.png

----------------------+
 PKGBUILD             |   95 +++++++++++++++++++++++++++++++++++++++++++++++++
 emby-theater.desktop |    6 +++
 emby-theater.png     |    1 
 3 files changed, 102 insertions(+)

Added: emby-theater/trunk/PKGBUILD
===================================================================
--- emby-theater/trunk/PKGBUILD	                        (rev 0)
+++ emby-theater/trunk/PKGBUILD	2021-10-05 20:24:11 UTC (rev 1027784)
@@ -0,0 +1,95 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+
+pkgname=emby-theater
+pkgver=3.0.15
+_libmpv_ver=2021_10_05
+pkgrel=1
+pkgdesc='An Electron app for Emby'
+arch=(x86_64)
+url=https://emby.media
+license=(GPL2)
+depends=(
+  at-spi2-atk
+  at-spi2-core
+  cairo
+  gcc-libs
+  glibc
+  libasound.so
+  libatk-1.0.so
+  libcups
+  libdbus-1.so
+  libdrm
+  libexpat.so
+  libfontconfig.so
+  libfreetype.so
+  libgdk-3.so
+  libgdk_pixbuf-2.0.so
+  libgio-2.0.so
+  libglib-2.0.so
+  libgobject-2.0.so
+  libgtk-3.so
+  libmfx
+  libpango-1.0.so
+  libpangocairo-1.0.so
+  libpulse.so
+  libuuid.so
+  libva-drm.so
+  libva.so
+  libx11
+  libxcb
+  libxcomposite
+  libxcursor
+  libxdamage
+  libxext
+  libxfixes
+  libxi
+  libxrandr
+  libxrender
+  libxss
+  libxtst
+  mesa
+  nspr
+  nss
+  ocl-icd
+  zlib
+)
+makedepends=(
+  git
+  npm
+)
+_commit=68ca6e4b9e3918dfd96bccef79d6a1937daf7e78
+#_tag=aeaab148c71414f5b6c29cfc0f7cf4eac0f95c55
+source=(
+  git+https://github.com/MediaBrowser/emby-theater-electron.git#commit=${_commit}
+  #git+https://github.com/MediaBrowser/emby-theater-electron.git#tag=${_tag}
+  https://mediabrowser.github.io/embytools/libmpv-${_libmpv_ver}-x64.tar.xz
+  emby-theater.desktop
+  emby-theater.png
+)
+b2sums=('SKIP'
+        '514898625050a05ccfd2c5b1eb4d57c459a538bbcae705a2c5fc0f9a6030ef6822375644909c399f447d2933f47f8002079a9a75232db56b6c54cf106f12d430'
+        '33b1230792bfc034d28fed21c60f9ecb3d7392293289a878866a20a505acabd03848df92300c9b1fd76d40ff03a6926451308c2b525ded0a75a17b77672c1e3b'
+        '130bcfad0a216d66e44e3551af14700b3745d55b89c4523543646ae0d1fc00f6787ad8ace827a47f0f671d340308e4529c91f1c018002e64c89cb0ca924aeb4b')
+
+prepare() {
+  cd emby-theater-electron
+  npm install
+  npm install electron-packager
+}
+
+build() {
+  cd emby-theater-electron
+  npx electron-packager . emby-theater --platform linux --arch x64
+}
+
+package() {
+  install -dm 755 "${pkgdir}"/usr/{bin,lib}
+  cp -dr --no-preserve='ownership' emby-theater-electron/emby-theater-linux-x64 "${pkgdir}"/usr/lib/emby-theater
+  rm -rf "${pkgdir}"/usr/lib/emby-theater/resources/app/libmpv/{arm,arm64,ia32,mpv-win32-*}
+  ln -s /usr/lib/emby-theater/emby-theater "${pkgdir}"/usr/bin/emby-theater
+  install -Dm 755 lib/libmpv.so* -t "${pkgdir}"/usr/lib/emby-theater/
+  install -Dm 644 emby-theater.desktop -t "${pkgdir}"/usr/share/applications/
+  install -Dm 644 emby-theater.png -t "${pkgdir}"/usr/share/pixmaps/
+}
+
+# vim: ts=2 sw=2 et:

Added: emby-theater/trunk/emby-theater.desktop
===================================================================
--- emby-theater/trunk/emby-theater.desktop	                        (rev 0)
+++ emby-theater/trunk/emby-theater.desktop	2021-10-05 20:24:11 UTC (rev 1027784)
@@ -0,0 +1,6 @@
+[Desktop Entry]
+Name=Emby Theater
+Exec=emby-theater
+Type=Application
+Icon=emby-theater
+Categories=AudioVideo;
\ No newline at end of file

Added: emby-theater/trunk/emby-theater.png
===================================================================
(Binary files differ)

Index: emby-theater/trunk/emby-theater.png
===================================================================
--- emby-theater/trunk/emby-theater.png	2021-10-05 19:51:55 UTC (rev 1027783)
+++ emby-theater/trunk/emby-theater.png	2021-10-05 20:24:11 UTC (rev 1027784)

Property changes on: emby-theater/trunk/emby-theater.png
___________________________________________________________________
Added: svn:mime-type
## -0,0 +1 ##
+image/png
\ No newline at end of property