[arch-commits] Commit in (6 files)

[David Runge]

    Date: Saturday, October 9, 2021 @ 23:11:40
  Author: dvzrv
Revision: 1029185

Add tuning-library as makedepends for bespokesynth.

Added:
  tuning-library/
  tuning-library/repos/
  tuning-library/trunk/
  tuning-library/trunk/PKGBUILD
  tuning-library/trunk/tuning-library-1.1.0-fix_missing_include.patch
  tuning-library/trunk/tuning-library-1.1.0-use_system_catch2.patch

------------------------------------------------+
 PKGBUILD                                       |   50 +++++++++++++++++++++++
 tuning-library-1.1.0-fix_missing_include.patch |    8 +++
 tuning-library-1.1.0-use_system_catch2.patch   |   21 +++++++++
 3 files changed, 79 insertions(+)

Added: tuning-library/trunk/PKGBUILD
===================================================================
--- tuning-library/trunk/PKGBUILD	                        (rev 0)
+++ tuning-library/trunk/PKGBUILD	2021-10-09 23:11:40 UTC (rev 1029185)
@@ -0,0 +1,50 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+pkgname=tuning-library
+pkgver=1.1.0
+pkgrel=1
+pkgdesc="Micro-tuning format parsing and frequency finding as a header-only C+ library"
+arch=('any')
+url="https://surge-synth-team.org/tuning-library/"
+license=('MIT')
+makedepends=('catch2' 'cmake')
+source=(
+  "$pkgname-$pkgver.tar.gz::https://github.com/surge-synthesizer/tuning-library/archive/refs/tags/release_${pkgver}.tar.gz"
+  "$pkgname-1.1.0-fix_missing_include.patch"
+  "$pkgname-1.1.0-use_system_catch2.patch"
+)
+sha512sums=('af924f622ffa220e15fcdae54e94fa93ac4fe3a65d8eebecee7a1cdb97458f5686712c08c9262a0d7b6b05521939faf97e3723396b94b125275de68fc29a8e9d'
+            '22602ae0b718d0aec7a4577180c9cdce904f5fbfe5347523173cbcaaffac8cd18815e624b86e92152d998b4d8a5fb7b802b4232c16f0afc29afe51a0eb9bac8e'
+            '96b5525911a42b43b0e6456307aa7b4b74ea2d2707bae6a4425b64cfedc7e1fcab9c89ace1fa75393cf0a4f684fd7fee6dcbf5988ee86208fbe9e4aa2a3dfeb1')
+b2sums=('6a201a08eadc2622e357d75d839d2d101dd1026e112bed6c11240f37aec5a12b1547da453ab88aa48b3da6a0df33dccc71c4d295be6a4ea439a5952db9706abf'
+        'c53fd874cb7a1333041e9255e6190a9d58466c7f6797b3a002e4e2aaf6daef4c20101c9b52e3b65439ac1d33f5ec4e23507155f0d14f3b37bad89b5518386b31'
+        '99c15cce7388e1bdcd7a349c72449d27760dc7718bc5919d819a1d7420dc0500c9b50bd99fa1d5d56ae80490f2870c05210888659b9a8e3f71a42e299161138a')
+
+prepare() {
+  mv -v "$pkgname-release_$pkgver" "$pkgname-$pkgver"
+  cd "$pkgname-$pkgver"
+  patch -Np1 -i ../"$pkgname-1.1.0-fix_missing_include.patch"
+  patch -Np1 -i ../"$pkgname-1.1.0-use_system_catch2.patch"
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  cmake -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_BUILD_TYPE='None' \
+        -Wno-dev \
+        -B build \
+        -S .
+  make VERBOSE=1 -C build
+}
+
+check() {
+  cd "$pkgname-$pkgver"
+  make VERBOSE=1 -k run-all-tests -C build
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  install -vDm 644 include/*.h -t "${pkgdir}/usr/include/"
+  install -vDm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -vDm 644 LICENSE.md -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}

Added: tuning-library/trunk/tuning-library-1.1.0-fix_missing_include.patch
===================================================================
--- tuning-library/trunk/tuning-library-1.1.0-fix_missing_include.patch	                        (rev 0)
+++ tuning-library/trunk/tuning-library-1.1.0-fix_missing_include.patch	2021-10-09 23:11:40 UTC (rev 1029185)
@@ -0,0 +1,8 @@
+diff -ruN a/commands/parsecheck.cpp b/commands/parsecheck.cpp
+--- a/commands/parsecheck.cpp	2021-07-01 20:32:19.000000000 +0200
++++ b/commands/parsecheck.cpp	2021-10-10 00:44:54.766530190 +0200
+@@ -1,3 +1,4 @@
++#include <cstring>
+ #include <iomanip>
+ #include "Tunings.h"
+ #include "TuningsImpl.h"

Added: tuning-library/trunk/tuning-library-1.1.0-use_system_catch2.patch
===================================================================
--- tuning-library/trunk/tuning-library-1.1.0-use_system_catch2.patch	                        (rev 0)
+++ tuning-library/trunk/tuning-library-1.1.0-use_system_catch2.patch	2021-10-09 23:11:40 UTC (rev 1029185)
@@ -0,0 +1,21 @@
+diff -ruN a/CMakeLists.txt b/CMakeLists.txt
+--- a/CMakeLists.txt	2021-07-01 20:32:19.000000000 +0200
++++ b/CMakeLists.txt	2021-10-10 00:56:11.485842867 +0200
+@@ -14,7 +14,6 @@
+ 
+ 
+ add_executable(tuning-library-tests)
+-target_include_directories(tuning-library-tests PRIVATE libs/catch2)
+ target_link_libraries(tuning-library-tests PRIVATE ${PROJECT_NAME})
+ target_sources(tuning-library-tests PRIVATE
+         tests/alltests.cpp)
+diff -ruN a/tests/alltests.cpp b/tests/alltests.cpp
+--- a/tests/alltests.cpp	2021-07-01 20:32:19.000000000 +0200
++++ b/tests/alltests.cpp	2021-10-10 00:57:22.469112753 +0200
+@@ -1,5 +1,5 @@
+ #define CATCH_CONFIG_RUNNER
+-#include "catch2.hpp"
++#include <catch2/catch.hpp>
+ 
+ #include "Tunings.h"
+ #include <iomanip>