[arch-commits] Commit in wayland/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Felix Yan]

    Date: Sunday, October 10, 2021 @ 22:35:54
  Author: felixonmars
Revision: 425758

archrelease: copy trunk to staging-x86_64

Added:
  wayland/repos/staging-x86_64/
  wayland/repos/staging-x86_64/PKGBUILD
    (from rev 425757, wayland/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: wayland/repos/staging-x86_64/PKGBUILD (from rev 425757, wayland/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2021-10-10 22:35:54 UTC (rev 425758)
@@ -0,0 +1,46 @@
+# Maintainer: Sébastien Luttringer <seblu at archlinux.org>
+# Contributor: Tom Gundersen <teg at jklm.no>
+# Contributor: Joel Teichroeb <joel at teichroeb.net>
+
+pkgbase=wayland
+pkgname=(wayland wayland-docs)
+pkgver=1.19.0
+pkgrel=2
+pkgdesc='A computer display server protocol'
+arch=('x86_64')
+url='https://wayland.freedesktop.org/'
+license=('MIT')
+depends=('glibc' 'libffi' 'expat' 'libxml2')
+makedepends=('meson' 'ninja' 'libxslt' 'doxygen' 'xmlto' 'graphviz' 'docbook-xsl')
+validpgpkeys=('C7223EBE4EF66513B892598911A30156E0E67611'  # Bryce Harrington
+              'C0066D7DB8E9AC6844D728715E54498E697F11D7'  # Derek Foreman
+              '34FF9526CFEF0E97A340E2E40FDE7BE0E88F5E48') # emersion <contact at emersion.fr>
+source=("https://wayland.freedesktop.org/releases/$pkgbase-$pkgver.tar.xz"{,.sig})
+sha256sums=('baccd902300d354581cd5ad3cc49daa4921d55fb416a5883e218750fef166d15'
+            'SKIP')
+
+build() {
+  meson build $pkgbase-$pkgver --buildtype=release --prefix=/usr
+  ninja -C build
+}
+
+check() {
+  ninja -C build test
+}
+
+package_wayland() {
+  DESTDIR="$pkgdir" ninja -C build install
+  mkdir -p docs/share
+  mv "$pkgdir"/usr/share/{doc,man} docs/share
+  install -Dm 644 $pkgbase-$pkgver/COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+}
+
+package_wayland-docs() {
+  pkgdesc+=" (documentation)"
+  depends=()
+
+  mv docs "$pkgdir/usr"
+  install -Dm 644 $pkgbase-$pkgver/COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+}
+
+# vim:set ts=2 sw=2 et: