[arch-commits] Commit in ruby-ffi/repos (2 files)

[Evangelos Foutras]

    Date: Sunday, October 10, 2021 @ 23:16:53
  Author: foutrelis
Revision: 1029332

archrelease: copy trunk to community-staging-x86_64

Added:
  ruby-ffi/repos/community-staging-x86_64/
  ruby-ffi/repos/community-staging-x86_64/PKGBUILD
    (from rev 1029331, ruby-ffi/trunk/PKGBUILD)

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Copied: ruby-ffi/repos/community-staging-x86_64/PKGBUILD (from rev 1029331, ruby-ffi/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-10-10 23:16:53 UTC (rev 1029332)
@@ -0,0 +1,56 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Mario Finelli <mario at finel dot li>
+# Contributor: Artem Vorotnikov <artem at vorotnikov dot me>
+
+_gemname=ffi
+pkgname=ruby-$_gemname
+pkgver=1.15.4
+pkgrel=2
+pkgdesc='Ruby FFI'
+arch=('x86_64')
+url='https://github.com/ffi/ffi'
+license=('BSD')
+depends=('ruby')
+makedepends=('ruby-rdoc')
+options=('!emptydirs')
+source=("https://rubygems.org/downloads/$_gemname-$pkgver.gem")
+noextract=("$_gemname-$pkgver.gem")
+sha512sums=('d8651df16f86250d887e9a9471a45c83f2687596ebfacf8b0471d404cb471fe3da5d6ba781884a7dd97b463fc393500265bb21b6b7afe5b8f70f7e90dc4537e3')
+
+package() {
+  local _gemdir="$(ruby -e'puts Gem.default_dir')"
+
+  gem install \
+    --verbose \
+    --ignore-dependencies \
+    --no-document \
+    --no-user-install \
+    --install-dir "$pkgdir/$_gemdir" \
+    --bindir "$pkgdir/usr/bin" \
+    "$_gemname-$pkgver.gem"
+
+  # delete unnecessary files & folders
+  cd "$pkgdir/$_gemdir"
+  find . -type f -name 'gem_make.out' -delete -o -name 'mkmf.log' -delete
+  rm -vrf cache
+  cd "gems/$_gemname-$pkgver"
+  rm -vrf Gemfile Rakefile "$_gemname.gemspec" ext rakelib
+  find lib/ffi/platform/* -prune -not -name "$CARCH-linux" -exec rm -rf {} +
+
+  # move documentation
+  install -vd "$pkgdir/usr/share/doc/$pkgname"
+  mv -v samples CHANGELOG.md README.md "$pkgdir/usr/share/doc/$pkgname"
+
+  # move licenses
+  install -vd "$pkgdir/usr/share/licenses/$pkgname"
+  mv -v LICENSE* COPYING "$pkgdir/usr/share/licenses/$pkgname"
+
+  # generate Ruby documentation
+  rdoc \
+    --format ri \
+    --output "$pkgdir$_gemdir/doc/$_gemname-$pkgver/ri" \
+    ./lib
+  # delete unnecessary artifacts
+  rm -rf "$pkgdir$_gemdir/doc/$_gemname-$pkgver/ri/"{lib,created.rid}
+}