[arch-commits] Commit in lib32-wayland/repos (2 files)
Felix Yan
felixonmars at gemini.archlinux.org
Sun Oct 10 23:24:40 UTC 2021
Date: Sunday, October 10, 2021 @ 23:24:40
Author: felixonmars
Revision: 1029344
archrelease: copy trunk to multilib-staging-x86_64
Added:
lib32-wayland/repos/multilib-staging-x86_64/
lib32-wayland/repos/multilib-staging-x86_64/PKGBUILD
(from rev 1029343, lib32-wayland/trunk/PKGBUILD)
----------+
PKGBUILD | 60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 60 insertions(+)
Copied: lib32-wayland/repos/multilib-staging-x86_64/PKGBUILD (from rev 1029343, lib32-wayland/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD (rev 0)
+++ multilib-staging-x86_64/PKGBUILD 2021-10-10 23:24:40 UTC (rev 1029344)
@@ -0,0 +1,60 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Tom Gundersen <teg at jklm.no>
+# Contributor: Sébastien Luttringer <sеblu@аrchlіnux․org>
+# Contributor: Joel Teichroeb <joel at teichroeb.net>
+
+pkgname=lib32-wayland
+pkgver=1.19.0
+pkgrel=2
+pkgdesc='A computer display server protocol'
+arch=(x86_64)
+url=https://wayland.freedesktop.org
+license=(MIT)
+depends=(
+ lib32-glibc
+ lib32-libffi
+ lib32-expat
+ lib32-libxml2
+ wayland
+)
+makedepends=(git)
+_tag=e60398b1755bfcdf09f040d3769131fe0d9762fc
+source=(git+https://gitlab.freedesktop.org/wayland/wayland.git#tag=${_tag})
+sha256sums=(SKIP)
+
+pkgver() {
+ cd wayland
+
+ git describe --tags
+}
+
+prepare() {
+ cd wayland
+
+ NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+ cd wayland
+
+ export CC='gcc -m32'
+ export PKG_CONFIG_PATH=/usr/lib32/pkgconfig
+
+ ./configure \
+ --prefix=/usr \
+ --libdir=/usr/lib32 \
+ --disable-documentation \
+ --disable-static
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+ make
+}
+
+package() {
+ make DESTDIR="${pkgdir}" -C wayland install
+ rm -rf "${pkgdir}"/usr/{bin,include,share}
+
+ install -dm 755 "${pkgdir}"/usr/share/licenses
+ ln -s wayland "${pkgdir}"/usr/share/licenses/lib32-wayland
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list