[arch-commits] Commit in (4 files)
Anatol Pomozov
anatolik at gemini.archlinux.org
Mon Oct 11 16:25:53 UTC 2021
Date: Monday, October 11, 2021 @ 16:25:52
Author: anatolik
Revision: 1029521
Add aws-crt-cpp to [community]
Added:
aws-crt-cpp/
aws-crt-cpp/repos/
aws-crt-cpp/trunk/
aws-crt-cpp/trunk/PKGBUILD
----------+
PKGBUILD | 32 ++++++++++++++++++++++++++++++++
1 file changed, 32 insertions(+)
Added: aws-crt-cpp/trunk/PKGBUILD
===================================================================
--- aws-crt-cpp/trunk/PKGBUILD (rev 0)
+++ aws-crt-cpp/trunk/PKGBUILD 2021-10-11 16:25:52 UTC (rev 1029521)
@@ -0,0 +1,32 @@
+# Maintainer: Anatol Pomozov
+
+pkgname=aws-crt-cpp
+pkgver=0.17.1
+pkgrel=1
+pkgdesc='C++ wrapper around the aws-c-* libraries. Provides Cross-Platform Transport Protocols and SSL/TLS implementations for C++.'
+arch=(x86_64)
+url='https://github.com/awslabs/aws-crt-cpp'
+license=(Apache)
+depends=(gcc-libs aws-c-common aws-c-http aws-c-mqtt aws-c-auth aws-c-s3 aws-c-event-stream)
+makedepends=(cmake)
+source=(aws-crt-cpp-$pkgver.zip::https://github.com/awslabs/aws-crt-cpp/archive/v$pkgver.zip)
+sha256sums=('26f98a1d7d3813987f62327ad217f155e5d13db7329db761b9e96be659219a31')
+
+build() {
+ cd aws-crt-cpp-$pkgver
+
+ cmake -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=/usr -DBUILD_SHARED_LIBS=ON -DBUILD_DEPS=OFF -S . -B build
+ cmake --build build
+}
+
+check() {
+ cd aws-crt-cpp-$pkgver
+ cmake --build build --target test
+}
+
+package() {
+ cd aws-crt-cpp-$pkgver
+
+ cmake --build build --target install -- DESTDIR="$pkgdir/"
+ install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
More information about the arch-commits
mailing list