[arch-commits] Commit in libvpx/repos (staging-x86_64 staging-x86_64/PKGBUILD)
Maxime Gauduin
alucryd at gemini.archlinux.org
Tue Oct 12 09:08:57 UTC 2021
Date: Tuesday, October 12, 2021 @ 09:08:57
Author: alucryd
Revision: 425808
archrelease: copy trunk to staging-x86_64
Added:
libvpx/repos/staging-x86_64/
libvpx/repos/staging-x86_64/PKGBUILD
(from rev 425807, libvpx/trunk/PKGBUILD)
----------+
PKGBUILD | 53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 53 insertions(+)
Copied: libvpx/repos/staging-x86_64/PKGBUILD (from rev 425807, libvpx/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2021-10-12 09:08:57 UTC (rev 425808)
@@ -0,0 +1,53 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+
+pkgname=libvpx
+pkgver=1.11.0
+pkgrel=1
+pkgdesc='VP8 and VP9 codec'
+arch=(x86_64)
+url=https://www.webmproject.org/
+license=(BSD)
+depends=(gcc-libs)
+makedepends=(
+ git
+ nasm
+)
+provides=(libvpx.so)
+_tag=626ff35955c2c35b806b3e0ecf551a1a8611cdbf
+source=(git+https://chromium.googlesource.com/webm/libvpx#tag=${_tag})
+sha256sums=(SKIP)
+
+pkgver() {
+ cd libvpx
+
+ git describe --tags | sed 's/^v//'
+}
+
+build() {
+ cd libvpx
+
+ ./configure \
+ --prefix=/usr \
+ --disable-install-docs \
+ --disable-install-srcs \
+ --enable-pic \
+ --enable-postproc \
+ --enable-runtime-cpu-detect \
+ --enable-shared \
+ --enable-vp8 \
+ --enable-vp9 \
+ --enable-vp9-highbitdepth \
+ --enable-vp9-temporal-denoising
+ make
+}
+
+package() {
+ cd libvpx
+
+ make DIST_DIR="${pkgdir}"/usr install
+ install -Dm 644 LICENSE -t "${pkgdir}"/usr/share/licenses/libvpx/
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list