[arch-commits] Commit in handbrake/repos (2 files)
Evangelos Foutras
foutrelis at gemini.archlinux.org
Tue Oct 12 10:36:25 UTC 2021
Date: Tuesday, October 12, 2021 @ 10:36:24
Author: foutrelis
Revision: 1029771
archrelease: copy trunk to community-staging-x86_64
Added:
handbrake/repos/community-staging-x86_64/
handbrake/repos/community-staging-x86_64/PKGBUILD
(from rev 1029770, handbrake/trunk/PKGBUILD)
----------+
PKGBUILD | 60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 60 insertions(+)
Copied: handbrake/repos/community-staging-x86_64/PKGBUILD (from rev 1029770, handbrake/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2021-10-12 10:36:24 UTC (rev 1029771)
@@ -0,0 +1,60 @@
+# Maintainer: Evangelos Foutras <evangelos at foutrelis.com>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+# Contributor: Sebastien Piccand <sebcactus gmail com>
+
+pkgname=('handbrake' 'handbrake-cli')
+pkgver=1.4.2
+pkgrel=2
+arch=('x86_64')
+url="https://handbrake.fr/"
+license=('GPL')
+_commondeps=('libxml2' 'libass' 'libvorbis' 'opus' 'speex' 'libtheora' 'lame'
+ 'x264' 'jansson' 'libvpx' 'libva' 'numactl' 'bzip2' 'gcc-libs'
+ 'zlib' 'xz' 'libjpeg-turbo')
+_guideps=('gst-plugins-base' 'gtk3' 'librsvg' 'libgudev')
+makedepends=('intltool' 'python' 'nasm' 'wget' 'cmake' 'meson'
+ "${_commondeps[@]}" "${_guideps[@]}")
+source=(https://github.com/HandBrake/HandBrake/releases/download/$pkgver/HandBrake-$pkgver-source.tar.bz2{,.sig})
+sha256sums=('8b8e81b7dc2e3180f4e94e8c7f5337d2953f69f0d983ccce48096e29ed6dfb61'
+ 'SKIP')
+validpgpkeys+=('1629C061B3DDE7EB4AE34B81021DB8B44E4A8645') # HandBrake Team <developers at handbrake.fr>
+
+prepare() {
+ cd "$srcdir/HandBrake-$pkgver"
+}
+
+build() {
+ cd "$srcdir/HandBrake-$pkgver"
+
+ ./configure \
+ --prefix=/usr \
+ --enable-qsv
+ make -C build
+}
+
+package_handbrake() {
+ pkgdesc="Multithreaded video transcoder"
+ depends=('desktop-file-utils' 'hicolor-icon-theme'
+ "${_commondeps[@]}" "${_guideps[@]}")
+ optdepends=('gst-plugins-good: for video previews'
+ 'gst-libav: for video previews'
+ 'intel-media-sdk: Intel QuickSync support'
+ 'libdvdcss: for decoding encrypted DVDs')
+
+ cd "$srcdir/HandBrake-$pkgver/build"
+
+ make DESTDIR="$pkgdir" install
+ rm "$pkgdir/usr/bin/HandBrakeCLI"
+}
+
+package_handbrake-cli() {
+ pkgdesc="Multithreaded video transcoder (CLI)"
+ depends=("${_commondeps[@]}")
+ optdepends=('intel-media-sdk: Intel QuickSync support'
+ 'libdvdcss: for decoding encrypted DVDs')
+
+ cd "$srcdir/HandBrake-$pkgver/build"
+ install -D HandBrakeCLI "$pkgdir/usr/bin/HandBrakeCLI"
+}
+
+# vim:set ts=2 sw=2 et:
More information about the arch-commits
mailing list