[arch-commits] Commit in (4 files)

[Bruno Pagani]

    Date: Sunday, October 17, 2021 @ 16:38:29
  Author: archange
Revision: 1030757

Initial addition of python-pytest-order required by spyder

Added:
  python-pytest-order/
  python-pytest-order/repos/
  python-pytest-order/trunk/
  python-pytest-order/trunk/PKGBUILD

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Added: python-pytest-order/trunk/PKGBUILD
===================================================================
--- python-pytest-order/trunk/PKGBUILD	                        (rev 0)
+++ python-pytest-order/trunk/PKGBUILD	2021-10-17 16:38:29 UTC (rev 1030757)
@@ -0,0 +1,37 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkg=pytest-order
+pkgname=python-${_pkg}
+pkgver=1.0.0
+pkgrel=1
+pkgdesc="pytest plugin that allows to customize the test execution order"
+arch=(any)
+url="https://github.com/pytest-dev/pytest-order/"
+license=(MIT)
+depends=(python-pytest)
+makedepends=(python-setuptools)
+checkdepends=(
+    python-pytest-dependency
+    python-pytest-mock
+    python-pytest-xdist
+)
+source=(${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('2761cbaa2de49e8deb2c15b50ae80f1db58925c03d427bd62d01146792cf8d3b')
+
+build() {
+  cd ${_pkg}-${pkgver}
+  python setup.py build
+}
+
+check() {
+  cd ${_pkg}-${pkgver}
+  python -m venv --system-site-packages test-env
+  test-env/bin/python setup.py install --skip-build
+  test-env/bin/python /usr/bin/pytest -v --color=yes
+}
+
+package() {
+  cd ${_pkg}-${pkgver}
+  python setup.py install --root=${pkgdir} --optimize=1 --skip-build
+  install -Dm644 LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}